ACC97: Search and Replace in Large Memo Field Causes IPF

• Microsoft Access 97

SYMPTOMS

Moderate: Requires basic macro, coding, and interoperability skills.

When you perform a search and replace in a Memo field containing more than 2052 characters, you receive one of the following error messages.

In Microsoft Windows 95

   This program has performed an illegal operation and will be shut
   down.

   MSACCESS caused an invalid page fault in MSACCESS.EXE.

In Microsoft Windows NT

   An application error has occurred and an application error log is
   being generated. MSACCESS.exe

RESOLUTION

The following example uses an update query that calls a user-defined function to do the search and replace:

1. Create a module and type the following line in the Declarations section if it is not already there:

         Option Explicit
   

2. Type the following procedure:

       Function ReplaceString(strSearch As String, strSearchFor As String, _
          strReplaceWith As String)
       On Error GoTo err_ReplaceString
           ' Searches the strSearch variable for strSearchFor
           ' and replaces it with strReplaceWith.
           Dim lngFoundLoc As Long    ' Location of match.
           Dim lngLenRemove As Long   ' Length of string being replaced.
           ' Set length of original text to skip.
           lngLenRemove = Len(strSearchFor)
           ' Set location of match.
           lngFoundLoc = InStr(1, strSearch, strSearchFor)
           ' If strSearchFor isn't found in strSearch
           ' just return the original string.
           If lngFoundLoc = 0 Then
               ReplaceString = strSearch
           ' If match is found, return original string up to match
           ' location, concatenate new text, and search the rest of
           ' the string recursively for additional matches.
           Else
               ReplaceString = Left(strSearch, lngFoundLoc - 1) & _
                   strReplaceWith & _
                   ReplaceString(Mid(strSearch, lngFoundLoc + _
                   lngLenRemove), strSearchFor, strReplaceWith)
           End If
       exit_ReplaceString:
           Exit Function
       ' Print error to Debug window and don't interrupt query.
       err_ReplaceString:
           Debug.Print "Error Replacing String """ & _
               strSearchFor & """ with """ & _
               strReplaceWith & """ in text """ & _
               strSearch & """"
           ' If there is an error, return original string
           ' and exit the function.
           ReplaceString = strSearch
           Resume exit_ReplaceString
       End Function
   
   

3. On the Debug menu, click "Compile and Save All Modules."

4. Create a new query and add the table containing the Memo field:

         Query: qryUpdateMemos
         --------------------------------------------------------------------
         Type: Update Query
   

         Field: <Name of Memo Field>
            Table: <Name of Table>
            Update To:
             ReplaceString([<Name of Memo Field>],[Search for],[Replace with])
             Criteria:
         Field: Instr(1,[<Name of Memo Field>], [Search for])
            Update To:
            Criteria: >0
   
   

5. On the Query menu, click Parameters.

6. On the first line of the grid, type "[Search for]" (without the quotation marks) in the Parameter field, and select Text from the Data Type box.

7. On the second line of the grid, type "[Replace With]" (without the quotation marks) in the Parameter field, and select Text from the Data Type box.

8. Run the query. Enter the text to search for and the text to replace with when prompted.

STATUS

Microsoft has confirmed this to be a problem in Microsoft Access 97. We are researching this problem and will post new information here in the Microsoft Knowledge Base as it becomes available.

MORE INFORMATION

Steps to Reproduce Problem

1. Start Microsoft Access and open a new blank database.

2. Create the following table:

         Table: tblMemoTable
         --------------------
         Field Name: MemoText
            Data Type: Memo
            Indexed: No
   
      Close the table and save it as tblMemoTable. When prompted if you want
      to create a primary key, click No.
   
   

3. Create a new module and type the following procedure:

         Function FillMemo(strTableName As String, _
            strFieldName As String)
   
            Dim db As Database
            Dim rs As Recordset
            On Error GoTo Err_FillMemo
            Set db = CurrentDb
            Set rs = db.OpenRecordset(strTableName)
            With rs
               .AddNew
               .Fields(strFieldName) = "abc" & String(2050, "x")
               .Update
            End With
            db.Close
         Exit_FillMemo:
            Exit Function
   
         Err_FillMemo:
            MsgBox CStr(Err) & " " & Err.Description
            Resume Exit_FillMemo
         End Function
   
   

4. Type the following line in the Debug window, and then press ENTER:

         ?FillMemo("tblMemoTable","MemoText")
   

5. Open tblTableMemo.

6. On the Edit menu, click Replace.

7. In the Replace In Field dialog box, type "abc" (without the quotation marks) in the Find What text box.

8. Type "hij" (without the quotation marks) in the Replace With text box, and then click to clear the Match Whole Field check box.

9. Click Replace. Note that you receive one of the errors described in the "Symptoms" section.

REFERENCES

For more information about creating update queries, search the Help Index for "update queries, creating" and select the Help Topic "Change records as a group using an update query," or ask the Microsoft Access 97 Office Assistant "How to create an update query."

For more information about writing recursive procedures, search the Help Index for "recursive procedures" and select the Help topic "Creating Recursive Procedures."