How to Create a List or Popup of Available Volume Names

• Microsoft Visual FoxPro for Macintosh, version 3.0b
• Microsoft FoxPro for Macintosh, version 2.5b

SUMMARY

In an application distributed to many users, who each have their own schemes for partitioning their hard disks and connecting to various network servers, you may find it useful to produce a list or popup of the available volumes. Below are several code samples showing how to create such an object.

MORE INFORMATION

You can manually create a popup (the kind controlled by a READ command) by incorporating the following code into a program:

   * Load FoxTools
   IF !'FOXTOOLS'$SET('LIBRARY')
     SET LIBRARY TO FOXTOOLS ADDITIVE
   ENDIF

   * Get the name of the boot volume
   sysDrive = JustDrive(FXSystem(0))

   * Remove the trailing colon
   sysDrive = LEFT(sysDrive, LEN(sysDrive) -1)

   * Create a popup containing all the volumes to which the Mac is
   * currently connected. The boot volume, the one containing the active
   * System Folder, is the default choice. Note the space after the caret
   * in the PICTURE clause.
   @1,1 GET m.volPop PICTURE '@^ ' + FXVolume() DEFAULT sysDrive
   READ  && Activate the list object

To create the same kind of popup or list using the Screen Builder, use the following code, which builds an array of volume names that can be used as the basis for a popup or list. You can place this procedure in the Cleanup and Procedures code snippet of a screen.

   PROCEDURE AVol
   * Procedure to create an array of available volumes.
   * The parameter must be passed by reference. When the procedure is
   * finished, the parameter will contain an array of the available
   * volumes.
   PARAMETER a_Volume

   IF PARAMETERS() < 1
     WAIT WINDOW 'Usage: =AVOL(@<expC>)' NOWAIT
     RETURN 0
   ENDIF

   *Open FoxTools if necessary
   IF !'FOXTOOLS'$SET('LIBRARY')
     SET LIBRARY TO FOXTOOLS ADDITIVE
   ENDIF

   * Get a semicolon-delimited list of available volumes
   volList=FXVolume()

   * Get the number of volumes in the list
   numVols = Words(volList,';')

   * Dimension the array to hold the volume names
   DIMENSION a_Volume(numVols)

   * Parse the list of volumes and stuff each value into its own array
   * element
   FOR i = 1 TO numVols
     a_Volume[i] = WordNum(volList, i, ';')
   ENDFOR

   RETURN numVols

   * END OF PROCEDURE AVol

   * Place the following in the SETUP code snippet of a screen
   theVols = ''
   volCount = AVol(@theVols)

For more information about the FoxTools functions used in this example, see the FoxTools README file located in the FOXPRO:GOODIES:MISC folder. This file contains a complete listing of all the functions in the FoxTools function library.