XL5: Visual Basic Examples Using DDE with Program Manager

The information in this article applies to:

• Microsoft Excel for Windows, versions 5.0, 5.0c

SUMMARY

The following information includes Visual Basic procedures that you can use in Microsoft Excel to return information from Program Manager and to perform actions on Program Manager groups and items using Dynamic Data Exchange (DDE) commands.

These examples demonstrate how to do the following:

• Create a New Group
• Delete an Existing Group
• Add a New Item
• Maximize, Minimize or Restore a Group Window
• Return a List of Groups

MORE INFORMATION

The application name for Program Manager is "ProgMan." The topic available in the Program Manager application is also "ProgMan." The following is a list of commands available in the ProgMan topic that you can use in a DDE conversation with Program Manager:

CreateGroup(GroupName,GroupPath)   Creates a new group at Program Manager
                                   or activates the window of an existing
                                   group.

DeleteGroup(GroupName)             Deletes an existing program group.

AddItem(CmdLine,Name,IconPath,     Creates a new program item (icon) in the
        IconIndex,xPos,yPos,       active group.
        DefDir,HotKey,,fMinimize)

ShowGroup(GroupName,ShowCommand)   Maximizes, minimizes, or restores a
                                   group window.

EXAMPLES

Create New Group

The following example creates a group called "Excel Files" or activates an existing group named "Excel Files" in Program Manager.

   Sub CreateGroup()
      Dim Chan As Integer
      Chan = DDEInitiate("Progman", "progman")
      DDEExecute Chan, "[CreateGroup(Excel Files)]"

      ' Terminate channel
      DDETerminate Chan
   End Sub

Delete Existing Group

The following example deletes the group "Excel Files." Note that the group is deleted even if it contains items.

   Sub DeleteGroup()

      Dim Chan As Integer
      Chan = DDEInitiate("Progman", "progman")
      DDEExecute Chan, "[DeleteGroup(Excel Files)]"

      ' Terminate channel
      DDETerminate Chan
   End Sub

Add New Item

The following example prompts you to enter a path to the item (c:\excel\excel.exe) and a name for the item (Excel), and then adds the item to the active group:

   Sub AddItem()
      Dim qt As String
      Dim Chan As Integer
      Dim path As String, item As String

      ' Set qt equal to quotation mark character
      qt = Chr(34)

      Chan = DDEInitiate("Progman", "progman")
      path = InputBox("Enter path for item")
      item = InputBox("Enter name for item")

      DDEExecute Chan, _
         "[AddItem(" & qt & path & qt & "," & qt & item & qt & ")]"

      ' Terminate channel
      DDETerminate Chan
   End Sub

Maximize, Minimize or Restore Group Window

   Sub GroupWindow()
      Dim Chan As Integer
      Chan = DDEInitiate("Progman", "progman")
      ' Maximize Excel Files group
      DDEExecute Chan, "[ShowGroup(Excel Files,3)]"
      ' Minimize Excel Files group
      DDEExecute Chan, "[ShowGroup(Excel Files,2)]"
      ' Restore Excel Files group
      DDEExecute Chan, "[ShowGroup(Excel Files,1)]"

      ' Terminate channel
      DDETerminate Chan
   End Sub

Return List of Groups

The following example returns a list of your Program Manager groups to Sheet1 in the active workbook:

Dim Chan as Integer Dim listing as Variant Dim i as Integer

   Sub ListGroups
      Chan = DDEInitiate("Progman","Progman")
      listing = DDERequest(Chan,"Progman")

      ' Terminate channel
      DDETerminate Chan

      i=1
      While i <= UBound(listing)
         Sheets("sheet1").Cells(i,1).FormulaR1C1=listing(i,1)
         i=i+1
      Wend

   End Sub

For additional information, please see the following article(s) in the Microsoft Knowledge Base:

   ARTICLE-ID: Q72907
   TITLE     : Manipulating Program Manager Groups Using DDE Interface

REFERENCES

For more information about the DDEExecute Method, the DDEInitiate Method, or the DDETerminate Method, choose the Search button in the Visual Basic Reference and type:

   DDE: channels