PPT: Sample Code to Find Slides that Don't Follow Slide Master

• Microsoft PowerPoint 98 Macintosh Edition
• Microsoft PowerPoint 97 for Windows

SUMMARY

This article contains a sample Microsoft Visual Basic for Applications macro (Sub procedure) that checks a presentation to see if any slides have backgrounds different from the Slide and/or Title Masters. If the macro finds a slide that has a different background, it displays the slide number in a message box at the end of the macro.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/default.asp

Sample Visual Basic Procedure

   Sub FollowMaster()

      ' Declare the variables.
      Dim OmitSlides() As String, Message As String
      Dim Index As Long, Count As Long, NumSlides As Long
      Dim CurrentSlide as Slide
      Dim Flag As Boolean

      ' Used to control the loop.
      Dim j As Long

      ' Initialize the index and flag.
      Index = -1
      Flag = False

      ' Get the number of slides.
      NumSlides = ActivePresentation.Slides.Count

      ' Loop through the slides.
      For j = 1 To NumSlides
         Set CurrentSlide = ActivePresentation.Slides(j)

         ' Check to see whether slide is different from master.
         If CurrentSlide.DisplayMasterShapes = msoFalse Or _
            CurrentSlide.FollowMasterBackground = msoFalse Then
            ' Add the slide number to an array.
            Index = Index + 1
            ReDim Preserve OmitSlides(Index)
            OmitSlides(Index) = j

            ' Set the flag to True if one slide is not following the
            ' master.
            If Flag = False Then
               Flag = True
            End If
         End If

      Next j

      ' Display the results.
      If Flag = False Then
         MsgBox "All slides are following the master.", vbInformation
      Else

         ' Start building message for the message box.
         If Index < 1 Then
            Message = "The following slide is NOT following the Master:" _
               & Chr(13)
         Else
            Message = "The following " & Index + 1 & " slides are NOT " _
               & "following the Master:" & Chr(13)
         End If

         ' Loop until slides finished.
         For j = 0 To Index
            Message = Message & Chr(13) & Chr(9) & "Slide #" & _
               OmitSlides(j)
         Next j

         ' Display the completed message box.
         MsgBox Message, vbInformation
      End If

   End Sub

REFERENCES

For more information about creating Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to create a macro," click Search, and then click to view "Create a macro in Visual Basic Editor."

For more information about running Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to run a macro," click Search, and then click to view "Run a macro."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q176476
   TITLE     : OFF: Office Assistant Not Answering Visual Basic Questions

   ARTICLE-ID: Q163435
   TITLE     : VBA: Programming Resources for Visual Basic for
               Applications