PPT97: Sample Code to Add a Media Object to a Running Slide Show

• Microsoft PowerPoint 98 Macintosh Edition
• Microsoft PowerPoint 97 for Windows

SUMMARY

This article provides a sample Microsoft Visual Basic for Applications macro (Sub procedure) that inserts a media object into a slide show and then places the object. The object is placed in the center of the slide.

NOTE: This macro must be run from an on-screen slide show. You can create an action button to run the macro, or you can change the action settings of another AutoShape so that it runs the macro when you click on the AutoShape.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/default.asp

Sample Visual Basic Procedure

   Sub AddMedia()

      ' Used for error trapping.
      On Error Resume Next
      Err.Clear

      ' The slide number to change.
      Const longSlideNumber As Long = 1

      ' Holds the path to the media object.
      Const stringPath = "c:\temp\"

      ' Holds the name of the file.
      Const stringName = "test.avi"

      ' Used to store an object reference to a shape.
      Dim shapeAVI As Shape

      Dim sswShow As SlideShowWindow

      ' Variables to store the slide height and width.
      Dim longSlideHeight As Long
      Dim longSlideWidth As Long

      ' Assign sswShow to the current show.
      Set sswShow = ActivePresentation.SlideShowWindow

      ' Check if they are in slide show.
      If Err.Number <> 0 Then
         MsgBox "This macro must be run from within a slide show. " _
           & "Modify the Action Settings of an object to run this macro." _
           , vbCritical, "Assign Macro to a Button"
         End
      End If

      ' Create the object.
      With ActivePresentation.Slides(longSlideNumber).Shapes
         Set shapeAVI = .AddMediaObject(stringPath & stringName, 0, 0)
      End With

      ' Set the play settings for the movie.
      With shapeAVI.AnimationSettings
         .PlaySettings.PlayOnEntry = msoTrue
         .AdvanceMode = ppAdvanceOnTime
         .AdvanceTime = 0
      End With

      ' Get the slide height and width.
      longSlideHeight = ActivePresentation.PageSetup.SlideHeight
      longSlideWidth = ActivePresentation.PageSetup.SlideWidth

      ' Center the media object horizontally.
      If shapeAVI.Width <= longSlideWidth Then
         shapeAVI.Left = ((longSlideWidth - shapeAVI.Width) \ 2)
      End If

      ' Center the media object vertically.
      If shapeAVI.Height <= longSlideHeight Then
         shapeAVI.Top = ((longSlideHeight - shapeAVI.Height) \ 2)
      End If

      ' Refresh the slide to get the animation to play.
      sswShow.View.GotoSlide (longSlideNumber)

   End Sub

REFERENCES

For more information about creating Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to create a macro," click Search, and then click to view "Create a macro in Visual Basic Editor."

For more information about running Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to run a macro," click Search, and then click to view "Run a macro."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q176476
   TITLE     : OFF: Office Assistant Not Answering Visual Basic Questions

   ARTICLE-ID: Q163435
   TITLE     : VBA: Programming Resources for Visual Basic for
               Applications