PPT: Sample VB Code to Check for Open Presentation

• Microsoft PowerPoint 98 Macintosh Edition
• Microsoft PowerPoint 97 for Windows

SUMMARY

This article contains a sample Microsoft Visual Basic for Applications function named IsPresentationOpen that determines whether a specific presentation is open. A sample macro (Sub procedure) named Driver is also included to demonstrate how to call the IsPresentationOpen function.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/default.asp

Sample Visual Basic Procedures

   Sub Driver()

      Dim IsOpen As Boolean

      ' Check to see whether test.ppt is open.
      IsOpen = IsPresentationOpen("test.ppt")

      ' Process the return value from IsPresentationOpen.
      If IsOpen = True Then
         MsgBox "The presentation is open.", vbInformation
      Else
         MsgBox "The Presentation is not open.", vbInformation
      End If

   End Sub

   ' Function Name: IsPresentationOpen()
   ' Arguments:     A string that represents the name of the presentation.
   '                The string can include the full path or just the
   '                presentation name.
   ' Returns:       True if the presentation is open
   '                False if the presentation is not open

   Function IsPresentationOpen(strPresName As String) As Boolean

      ' An object reference to a presentation.
      Dim oPresObject As Presentation

      Dim boolIsFullPath As Boolean

      ' Check to see whether the full path was passed.
      If (InStr(1, strPresName, ":\")) = 0 Then
         boolIsFullPath = False
      Else
         boolIsFullPath = True
      End If

      ' Loop through the open presentations.
      For Each oPresObject In PowerPoint.Presentations

         If boolIsFullPath = True Then

            ' Check for a match.
            If (StrComp(oPresObject.FullName, _
                     strPresName, _
                     vbTextCompare) = 0) Then

               IsPresentationOpen = True
               Exit Function
            End If

         Else

            ' Check for a match.
            If (StrComp(oPresObject.Name, _
                     strPresName, _
                     vbTextCompare) = 0) Then
               IsPresentationOpen = True
               Exit Function
            End If

         End If

      Next oPresObject

      ' No match found.
      IsPresentationOpen = False

   End Function

REFERENCES

For more information about creating Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to create a macro," click Search, and then click to view "Create a macro in Visual Basic Editor."

For more information about running Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to run a macro," click Search, and then click to view "Run a macro."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q176476
   TITLE     : OFF: Office Assistant Not Answering Visual Basic Questions

   ARTICLE-ID: Q163435
   TITLE     : VBA: Programming Resources for Visual Basic for
               Applications