ACC97: Example Using a Callback Procedure with Balloons

• Microsoft Access 97

SUMMARY

Advanced: Requires expert coding, interoperability, and multiuser skills.

This article demonstrates how to use the Callback property of a Balloon object to determine which check boxes a user selected, or which label or button a user clicked, and then to respond to that selection.

This article assumes that you are familiar with Visual Basic for Applications and with creating Microsoft Access applications using the programming tools provided with Microsoft Access. For more information about Visual Basic for Applications, please refer to the "Building Applications with Microsoft Access 97" manual.

NOTE: A demonstration of the technique used in this article can be seen in the sample file, FrmSmp97.exe. For information about how to obtain this sample file, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q175066
   TITLE     : ACC97: Microsoft Access 97 Sample Forms Available on MSL

MORE INFORMATION

A balloon is the area in which the Microsoft Office Assistant displays headings and text, similar to a message box. In addition to headings and text, a balloon may contain other types of controls, such as check boxes, buttons, and labels which are similar to option buttons.

To determine which label or button a user clicked, or which check boxes a user selected in a balloon, you must create a Callback procedure and set the balloon's Callback property to the name of that procedure. A Callback procedure is a procedure that runs whenever a modeless balloon is displayed.

To display a balloon with multiple buttons, labels, and check boxes, follow these steps:

1. Create a module and type the following line in the Declarations section if it is not already there:

         Option Explicit
   

2. On the Tools menu, click References, and then click Microsoft Office 8.0 Object Library to add it as a reference. If you do not see it in the list, search your hard drive for the file, MSO97.DLL.

3. Type the following procedure:

         Sub OpenBalloon()
            Dim offBalloon As Office.Balloon
            Set offBalloon = Application.Assistant.NewBalloon
            With offBalloon
               ' Show the Office Assistant.
               .Parent.Visible = True
   
               ' Set the heading and text of the balloon.
               .Heading = "Welcome to the Microsoft Office 97 Assistant!"
               .Text = "Click one or more of the check boxes below, and " _
                      & "also click either a label or a button."
   
               ' Make the balloon modeless.
               .Mode = msoModeModeless
   
               ' Display the Back, Next, and Close Buttons.
               ' To determine the constants for other buttons you can place
               ' on a balloon, view the Microsoft Office 8.0 Object library
               ' in the Object Browser.
               .Button = msoButtonSetBackNextClose
   
               ' Display two check boxes.
               .Checkboxes(1).Text = "Checkbox 1"
               .Checkboxes(2).Text = "Checkbox 2"
   
               ' Display two labels.
               .Labels(1).Text = "Label 1"
               .Labels(2).Text = "Label 2"
   
               ' Define which Callback procedure to run.
               .Callback = "WhichButton"
               .Show
            End With
         End Sub
   
   

4. Following is an example of a Callback procedure written to use with the procedure demonstrated above. Note that the Callback procedure accepts three arguments: bln, iBtn, and iPriv. All Callback procedures you write for use with balloons must accept these three arguments.

   The first argument, bln, defines the Balloon object that called the procedure. The second argument, iBtn, defines the value of the button or label the user clicked. Using the iBtn argument, you can determine which button or label the user clicked. The third argument, iPriv, defines the value that uniquely identifies the balloon that called the procedure. The difference between the bln and iPriv arguments is that a programmer can use the iPriv argument to uniquely identify which balloon called the procedure. This allows a programmer to write one Callback procedure to use with all balloons, rather than to write a separate Callback procedure for each Balloon.

   Type the following procedure:

         Sub WhichButton(bln As Balloon, iBtn As Long, iPriv As Long)
            Dim cBox As Office.BalloonCheckbox
   
            bln.Close
            For Each cBox In bln.Checkboxes
               If cBox.Checked Then
                  MsgBox "Selected " & cBox.Item
               End If
            Next
            Select Case iBtn
               Case 1
                  MsgBox "Clicked Label 1"
               Case 2
                  MsgBox "Clicked Label 2"
               Case msoBalloonButtonBack
                  MsgBox "Clicked Back Button"
               Case msoBalloonButtonClose
                  MsgBox "Clicked Close Button"
               Case msoBalloonButtonNext
                  MsgBox "Clicked Next Button"
            End Select
         End Sub
   
   

5. To test these procedures, type the following line in the Debug window, and then press ENTER.

          OpenBalloon
   

   Note that the Microsoft Office Assistant is displayed with a new balloon that contains multiple check boxes, labels, and buttons.

6. Click one or more of the check boxes and either a button or a label. Note that you receive message boxes indicating which check boxes you selected and which button or label you clicked.

REFERENCES

For more information about using the Callback property with the Microsoft Office Assistant, search the Help Index for "Callback property."