PPT97: Viewer Quit Method Does Not Close Viewer

• Microsoft PowerPoint 97 for Windows

SYMPTOMS

Microsoft PowerPoint Viewer 97 remains running after the Quit method is carried out in a Microsoft Visual Basic for Applications procedure.

CAUSE

This problem occurs if you obtain a PowerPoint Viewer 97 object reference while PowerPoint Viewer is running.

WORKAROUND

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/default.asp

NOTE: The following code does not close PowerPoint Viewer if it is showing a presentation.

   Declare Function FindWindow Lib "user32" Alias _
      "FindWindowA" (ByVal lpClassName As Long, _
      ByVal lpWindowName As String) As Long

   Declare Function SendMessage Lib "user32" Alias _
      "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
      ByVal wParam As Long, lParam As Any) As Long

   Sub QuitViewer97()

      Const WM_CLOSE As Long = &H10

      Dim hwnd As Long, lReturn As Long

      ' Get a handle to the PowerPoint Viewer 97 window.
      hwnd = FindWindow(0&, "Microsoft PowerPoint Viewer")

      ' Verify the handle is valid.
      If hwnd = 0 Then
         MsgBox "Unable to obtain Viewer 97 window handle." _
            & vbCrLf + "The Viewer may not be running.", vbInformation
         End
      End If

      ' Send the close message to PowerPoint Viewer 97.
      lReturn = SendMessage(hwnd, WM_CLOSE, 0&, 0&)

      ' Verify the SendMessage command was successful.
      If lReturn = 0 Then
         MsgBox "Microsoft PowerPoint Viewer 97 has been closed.", _
            vbInformation
      Else
         MsgBox "Unable to close Microsoft PowerPoint Viewer 97", _
         vbInformation
      End If

   End Sub

REFERENCES

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q163435
   TITLE     : VBA: Programming Resources for Visual Basic for
               Applications