PPT97: Sample Code to Copy All Objects to a New Presentation

• Microsoft PowerPoint 97 for Windows

SUMMARY

This article provides a sample Microsoft Visual Basic for Applications macro that copies all objects from the original presentation to a new presentation created by the macro. This macro can be used to try to recover data from large presentations that may be damaged.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/default.asp

Sample Visual Basic Procedure

   Sub CopyPaste()

      ' Declare variables.
      Dim intCount As Long
      Dim intLoop As Long

      ' Returns the number of slides in the damaged presentation.
      intCount = ActivePresentation.Slides.Count

      ' Creates new, blank presentation named "Newfile". Then
      ' adds a new blank slide in the first index position.
      Presentations.Add.SaveAs "Newfile"
      Presentations("Newfile").Slides.Add 1, ppLayoutBlank

      ' Loops through count of slides.
      For intLoop = 1 To intCount

         ' After creating the new presentation, the damaged
         ' presentation automatically becomes the second window
         ' index item in the PowerPoint window. This line of
         ' code switches to the damaged presentation.
         Windows.Item(2).Activate
         ActiveWindow.View.GotoSlide (intLoop)

         ' Selects and copies objects on active slide.
         ActiveWindow.Selection.SlideRange.Shapes.SelectAll
         ActiveWindow.Selection.Copy

         ' After switching to the new presentation, the index
         ' position of the two presentations swaps, so to go
         ' back to the new presentation, you must go to the second
         ' index position in the windows item list.
         Windows.Item(2).Activate
         ActiveWindow.View.GotoSlide (intLoop)

         ' Pastes objects to active slide in new presentation.
         ActiveWindow.View.Paste

         ' Adds new, blank slide to new presentation if there are
         ' more slides to process.
         If intLoop < intCount Then
            Presentations("Newfile").Slides.Add intLoop + 1, ppLayoutBlank
         End If
      Next intLoop

      ' Tells user that operation has completed.
      MsgBox "Operation Complete!"

   End Sub

REFERENCES

For more information about creating Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to create a macro," click Search, and then click to view "Create a macro in Visual Basic Editor."

For more information about running Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type "how to run a macro," click Search, and then click to view "Run a macro."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q176476
   TITLE     : OFF: Office Assistant Not Answering Visual Basic Questions

   ARTICLE-ID: Q163435
   TITLE     : VBA: Programming Resources for Visual Basic for
               Applications