WD97: Example Macro to Send E-mail Using MAPI Commands

• Microsoft Word 97 for Windows

SUMMARY

This article includes a sample Visual Basic for Applications macro that uses MAPI commands to send an e-mail message.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

   http://www.microsoft.com/support/supportnet/refguide/default.asp

   Sub MapiSendMail()
      Dim objSession As Object
      Dim objMessage As Object
      Dim objRecipient As Object
      Dim sProfile As String
      Dim sSubjPrmpt As String
      Dim sTextPrmpt As String
      Dim sEmailPrmpt As String
      Dim sMsgTitle As String
      ' Leaving sProfile equal to Null will
      ' force the user to select which Mapi
      ' profile to use. To keep from being
      ' prompted, you must supply a valid
      ' user profile.
      sProfile = ""
      sEmailPrmpt = "Enter valid Email Name of message recipient:"
      sSubjPrmpt = "Enter the subject line for this message:"
      sTextPrmpt = "Enter the text for this message:"
      sMsgTitle = "Mapi Macro Example"
      ' Create the Session Object.
      Set objSession = CreateObject("mapi.session")
      ' Log on using the session object.
      ' Specify a valid profile name if you want to
      ' avoid the logon dialog box.
      objSession.Logon profileName:=sProfile
      ' Add a new message object to the OutBox.
      Set objMessage = objSession.Outbox.Messages.Add
      ' Set the properties of the message object.
      objMessage.Subject = InputBox(sSubjPrmpt, sMsgTitle)
      objMessage.Text = InputBox(sTextPrmpt, sMsgTitle)
      ' Add a recipient object to the objMessage.Recipients collection.
      Set objRecipient = objMessage.Recipients.Add
      ' Set the properties of the recipient object.
      objRecipient.Name = InputBox(sEmailPrmpt, sMsgTitle)
      objRecipient.Resolve
      ' Send the message. Setting showDialog to False
      ' sends the message without displaying the message
      ' or requiring user intervention. A setting of True
      ' displays the message and the user must choose
      ' to Send from within the message dialog.
      objMessage.Send showDialog:=False
      MsgBox "Message sent successfully!"
      ' Log off using the session object.
      objSession.Logoff
   End Sub

REFERENCES

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q163435
   TITLE     : VBA: Programming Resources for Visual Basic for
               Applications