How To Create a Basic Add-In Using Visual Basic 4.0

The heart of the add-in is the public-creatable OLE automation object. The following are the steps for creating this object:

   a. Add a new Class (.cls) module to the project.
   b. Set the following properties on the new class:

      Property                Value
      --------------------------------------------------------------
      Instancing              2 - Creatable MultiUse
      Name                    MinimalAddIn
      Public                  True

When the automation manager loads an add-in, it looks for and calls the ConnectAddin method. The add-in manager passes an instance of the Application object to the ConnectAddin method. The add-in can then use this object for automating the Visual Basic design environment. In the minimal add-in, show a message in this method of the class with the following code:

   Public Sub ConnectAddIn(VBInstance As Object)
      MsgBox "ConnectAddIn"
   End Sub

   Public Sub DisconnectAddIn()
      MsgBox "DisconnectAddIn"
   End Sub

At this point you have added all the code necessary for the minimal add-in. However, you need to set the project options to expose this project as an OLE automation server. Set the following in the Tools/Options dialog box:

   Option                  Value
   -----------------------------------------------------------
   Start up Form           Sub Main
   Project Name            Example
   Start Mode              OLE Server
   Error Trapping          Break in Class Module

Now you need to make the minimal add-in available to the Add-In manager. The add-in looks in Vb.ini under either the Add-Ins16 or Add-Ins32 section depending on whether you are running the 16-bit or 32-bit versions of Visual Basic. The add-in manager looks for available add-ins in the form of ProgID=n, where ProgID is the OLE Automation ProgID for your class and n is 0 or 1. 0 means the add-in is available but Visual Basic doesn't have it loaded. 1 means that the add-in is or should be loaded. For the minimal add- in in 32-bit Visual Basic, you need to add the following to the Vb.ini:

   [Add-Ins32]
   Example.MinimalAddIn=0

That is it for the minimal add-in. Now you can test it. Go ahead and start up the add-in by running the project. To test it you must start up a second instance of Visual Basic. In the second instance, bring up the Add-In Manager dialog box. There should be a check box with ProgID Example.MinimalAddin next to it. Check the box and click OK. The Add-In Manager will call the ConnectAddin method of the minimal add-in and the add- in will display the message box "ConnectAddIn."

Now go back to the Add-In Manager in the second instance of Visual Basic. Clear Example.MinimalAddin and click OK. The Add-In Manager will call the DisconnectAddIn method and the add-in will display the message box "DisconnectAddIn."

EXPANDING THE MINIMAL ADD-IN

The minimal add-in demonstrated the absolute minimum requirements for creating an add-in. However, there are some basic things that most add-ins need to do. In this section you will expand upon the minimal add-in to create a basic add-in that automatically adds itself to Vb.ini and adds a menu to the Visual Basic Add-In menu.

1. Reference VBIDE

In the minimal add-in you did not use the Visual Basic IDE add-in object model. Any add-in that needs to program the IDE must add a reference to the "Microsoft Visual Basic 4.0 Development Environment" object library. Almost all add-ins need to add a reference to this library. For the basic add-in, we need to use the library to declare variables and to add a menu. So, add a reference to this library in the Tools/References dialog box.

1. Change the Class Name

To help distinguish the basic add-in from the minimal add-in, change the Name property of the class module to BasicAddIn.

1. Store the Instance of the Application Object

Most add-ins need to store the instance of the Application object that is passed in through the ConnectAddIn method so that it can be used later to automate the IDE. For the basic add-in, this means that you need to declare an object in the class to store the instance. To do this you need to add the following to the general declarations section of the class:

   Private ThisInstance As VBIDE.Application

   Public Sub ConnectAddIn(VBInstance As Object)
      Set ThisInstance = VBInstance
   End Sub

The majority of add-ins also need to add a menu item to the Add-In menu so that users can trigger some functionality in their add-in. In the basic add- in, you simply show a message if the user clicks the menu item. Before adding the code to create the menu, you need to add two variables to the general declarations section of the class:

   Private AddInMenuLine As VBIDE.MenuLine
   Private hMenuLine As Long

Now you can add the code necessary for adding the MenuLine to the ConnectAddIn method:

   Set AddInMenuLine = ThisInstance.AddInMenu.MenuItems.Add("Basic Add-In")

After adding the MenuLine you need to connect the MenuLine to an event handler. In this case the AfterClick event of the MenuLine object is what you want to handle. First you need to create an event handler for the AfterClick in the class. The AfterClick event handler should look like the following:

   Public Sub AfterClick()
      MsgBox "Basic Add-In Example"
   End Sub

   hMenuLine = AddInMenuLine.ConnectEvents(Me)

   AddInMenuLine.DisconnectEvents hMenuLine
   ThisInstance.AddInMenu.MenuItems.Remove AddInMenuLine

  Option Explicit

  Private ThisInstance As VBIDE.Application
  Private AddInMenuLine As VBIDE.MenuLine
  Private hMenuLine As Long

  Public Sub ConnectAddIn(VBInstance As Object)
     Set ThisInstance = VBInstance
     Set AddInMenuLine = ThisInstance.AddInMenu.MenuItems.Add("Basic Add-

     hMenuLine = AddInMenuLine.ConnectEvents(Me)
  End Sub

  Public Sub DisconnectAddIn(Mode As Integer)
     AddInMenuLine.DisconnectEvents hMenuLine
     ThisInstance.AddInMenu.MenuItems.Remove AddInMenuLine
  End Sub

  Public Sub AfterClick()
     MsgBox "Basic Add-In Example"
  End Sub

In the minimal add-in, you added the add-in to the Vb.ini by hand. However, it is much easier for the user to install the add-in if it does this automatically. To do this requires the use of GetPrivateProfileString to check if it has already been added and WritePrivateProfileString to add it if it isn't there. A good place to put this code is in the Sub Main for EXE servers. However, for DLL servers, the Sub Main is not executed so this does not work. If you are creating a DLL server you will have to put this code somewhere else, such as in your setup program:

   #If Win16 Then
      Declare Function WritePrivateProfileString Lib "KERNEL" ( _
         ByVal AppName As String, ByVal KeyName As String, _
         ByVal keydefault As String, ByVal FileName As String) As Integer
      Declare Function GetPrivateProfileString Lib "KERNEL" ( _
         ByVal AppName As String, ByVal KeyName As String, _
         ByVal keydefault As String, ByVal ReturnString As String, _
         ByVal NumBytes As Integer, ByVal FileName As String) As Integer
   #ElseIf Win32 Then
      Declare Function WritePrivateProfileString Lib "KERNEL32" _
         Alias "WritePrivateProfileStringA" (ByVal AppName As String, _
         ByVal KeyName As String, ByVal keydefault As String, _
         ByVal FileName As String) As Long
      Declare Function GetPrivateProfileString Lib "KERNEL32" _
         Alias "GetPrivateProfileStringA" (ByVal AppName As String, _
         ByVal KeyName As String, ByVal keydefault As String, _
         ByVal ReturnString As String, ByVal NumBytes As Long, _
         ByVal FileName As String) As Long
   #End If

   Sub Main()
      #If Win16 Then
         Const Section = "Add-Ins16"
      #ElseIf Win32 Then
         Const Section = "Add-Ins32"
      #End If
      Const BufSize = 255

      Dim Ret As Variant
      Dim RetStr As String

      'Check to see if the entry is already in the Vb.ini file.
      'Add if not.

      RetStr = Space(BufSize)
      Ret = GetPrivateProfileString(Section, "Example.BasicAddin", _
         "NotFound", RetStr, BufSize, "VB.INI")
      RetStr = Left(RetStr, Ret)
      If RetStr = "NotFound" Then
         WritePrivateProfileString Section, "Example.BasicAddin", _
            "0", "VB.INI"
      End If
   End Sub