PRB: All Parameters of Choose Function Are Evaluated

• Microsoft Visual Basic Control Creation, Learning, Professional, and Enterprise Editions for Windows, version 5.0
• Microsoft Visual Basic Standard, Professional, and Enterprise Editions for Windows, version 4.0

SYMPTOMS

When you specify functions as the Choice arguments in a Choose function, all functions are executed.

CAUSE

The Choose function allows you to select a value from a list of choices based on the value passed as the index. For example, the following statement would result in x being assigned the value "b":

   x = Choose(2, "a", "b", "c")

   x = Choose(2, MyFunction1(), MyFunction2(), MyFunction3())

Choose is implemented as a function with a parameter array and every parameter must be evaluated before it can be passed to the Choose function.

Visual Basic's implementation of the Choose function can be duplicated with the following function:

   Public Function MyChoose(Index As Single, ParamArray Choice())
      On Error GoTo BadChoice
      If IsObject(Choice(Index - 1)) Then
         Set MyChoose = Choice(Index - 1)
      Else
         MyChoose = Choice(Index - 1)
      End If
      Exit Function
   BadChoice:
      MyChoose = Null
   End Function

RESOLUTION

Because this behavior is by design, another approach must be taken to avoid all parameters being evaluated. The logic of the Choose function can easily be broken down into an equivalent "If...Then...ElseIf" statement or a "Select Case" statement.

Sample Choose Statement

   result = Choose(MyIndex, MyFunction1(), MyFunction2(), MyFunction3())

Equivalent 'If...Then...ElseIf' Statement

   If MyIndex = 1 Then
      result = MyFunction1()
   ElseIf MyIndex = 2 Then
      result = MyFunction2()
   ElseIf MyIndex = 3 Then
      result = MyFunction3()
   Else
      result = Null
   End If

   Select Case MyIndex
      Case 1
         result = MyFunction1()
      Case 2
         result = MyFunction2()
      Case 3
         result = MyFunction3()
      Case Else
         result = Null
   End Select

STATUS

This behavior is by design.

MORE INFORMATION

Steps to Reproduce Behavior

1. Create a new Visual Basic project. Form1 is created by default.

2. Add a Command button to Form1.

3. Add the following code to Form1:

         Option Explicit
   

         Private Function MyFunction1() As Long
            Debug.Print "MyFunction1"
            MyFunction1 = 1
         End Function
   
         Private Function MyFunction2() As Long
            Debug.Print "MyFunction2"
            MyFunction2 = 2
         End Function
   
         Private Function MyFunction3() As Long
            Debug.Print "MyFunction3"
            MyFunction3 = 3
         End Function
   
         Private Sub Command1_Click()
            Dim result
            result = Choose(2, MyFunction1(), MyFunction2(), MyFunction3())
         End Sub
   
   

4. Save and run the project.

5. Click the CommandButton. Note that the "Debug.Print" statements from the three user-defined functions are executed even though the result of MyFunction2 is the returned value.

REFERENCES

Visual Basic's Online Help for the Choose function.

Keywords          : VB4WIN vb5all
Version           : WINDOWS:4.0,5.0
Platform          : WINDOWS
Issue type        : kbprb