HOWTO: Use the System Tray Directly from Visual Basic 5.0

• Microsoft Visual Basic Control Creation, Learning, Professional, and Enterprise Editions for Windows, version 5.0

SUMMARY

This article demonstrates how to take full advantage of the Windows System Tray using Visual Basic 5.0. It places an icon of your choice into the System Tray that will display a ToolTip of your choice when the mouse is rested over it, will restore the application when clicked, and will display a popup menu when right-clicked. This is all possible because of Visual Basic 5.0's ability to directly handle callbacks, therefore taking full advantage of the Shell_NotifyIcon function that is exported by Shell32.dll.

MORE INFORMATION

The following example can be added to any Visual Basic 5.0 Project that has at least one form and a standard module.

Step-by-Step Example:

1. Add the following code to the declarations section of a standard module in your project:

         'user defined type required by Shell_NotifyIcon API call
         Public Type NOTIFYICONDATA
          cbSize As Long
          hwnd As Long
          uId As Long
          uFlags As Long
          uCallBackMessage As Long
          hIcon As Long
          szTip As String * 64
         End Type
   

         'constants required by Shell_NotifyIcon API call:
         Public Const NIM_ADD = &H0
         Public Const NIM_MODIFY = &H1
         Public Const NIM_DELETE = &H2
         Public Const NIF_MESSAGE = &H1
         Public Const NIF_ICON = &H2
         Public Const NIF_TIP = &H4
         Public Const WM_MOUSEMOVE = &H200
         Public Const WM_LBUTTONDOWN = &H201     'Button down
         Public Const WM_LBUTTONUP = &H202       'Button up
         Public Const WM_LBUTTONDBLCLK = &H203   'Double-click
         Public Const WM_RBUTTONDOWN = &H204     'Button down
         Public Const WM_RBUTTONUP = &H205       'Button up
         Public Const WM_RBUTTONDBLCLK = &H206   'Double-click
      
         Public Declare Function SetForegroundWindow Lib "user32" _
         (ByVal hwnd As Long) As Long
         Public Declare Function Shell_NotifyIcon Lib "shell32" _
         Alias "Shell_NotifyIconA" _
         (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean
      
         Public nid As NOTIFYICONDATA
   
   

2. Add the following code to any form in your project that you want to respond to the System Tray Icon for your application:

         Private Sub Form_Load()
          'the form must be fully visible before calling Shell_NotifyIcon
          Me.Show
          Me.Refresh
          With nid
           .cbSize = Len(nid)
           .hwnd = Me.hwnd
           .uId = vbNull
           .uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
           .uCallBackMessage = WM_MOUSEMOVE
           .hIcon = Me.Icon
           .szTip = "Your ToolTip" & vbNullChar
          End With
          Shell_NotifyIcon NIM_ADD, nid
         End Sub
      
         Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As
      _
            Single, Y As Single)
         'this procedure receives the callbacks from the System Tray icon.
         Dim Result As Long
         Dim msg As Long
          'the value of X will vary depending upon the scalemode setting
          If Me.ScaleMode = vbPixels Then
           msg = X
          Else
           msg = X / Screen.TwipsPerPixelX
          End If
          Select Case msg
           Case WM_LBUTTONUP        '514 restore form window
            Me.WindowState = vbNormal
            Result = SetForegroundWindow(Me.hwnd)
            Me.Show
           Case WM_LBUTTONDBLCLK    '515 restore form window
            Me.WindowState = vbNormal
            Result = SetForegroundWindow(Me.hwnd)
            Me.Show
           Case WM_RBUTTONUP        '517 display popup menu
            Result = SetForegroundWindow(Me.hwnd)
            Me.PopupMenu Me.mPopupSys
          End Select
         End Sub
      
         Private Sub Form_Resize()
          'this is necessary to assure that the minimized window is hidden
          If Me.WindowState = vbMinimized Then Me.Hide
         End Sub
      
         Private Sub Form_Unload(Cancel As Integer)
          'this removes the icon from the system tray
          Shell_NotifyIcon NIM_DELETE, nid
         End Sub
      
         Private Sub mPopExit_Click()
          'called when user clicks the popup menu Exit command
          Unload Me
         End Sub
      
         Private Sub mPopRestore_Click()
          'called when the user clicks the popup menu Restore command
          Me.WindowState = vbNormal
          Result = SetForegroundWindow(Me.hwnd)
          Me.Show
         End Sub
   
   

3. Make the following Property Settings on the same form to which you added the above code:

      Property         Required Setting for System Tray example
      ---------------------------------------------------------------
      Icon           = The icon you want to appear in the system tray.
      Minbutton      = True
      ShownInTaskbar = False
   
   

4. Add the following Menu items to the same form using the Menu Editor:

      Caption      Name          Enabled   Visible   Position
      ---------------------------------------------------------
      &SysTray     mPopupSys      True      False    Main Level
      &Restore     mPopRestore    True      True     Inset one
      &Exit        mPopExit       True      True     Inset one
   
   

System Tray Flexibility

You can modify the ToolTip that appears over the System Tray icon by changing the following line in the Form_Load procedure:

   .szTip = "Your ToolTip" & vbNullChar

You can modify the Icon that appears in the System Tray by changing the following line in the Form_Load procedure:

   .hIcon = Me.Icon

You can change any of the System Trays settings at any time after the use of the NIM_ADD constant by reassigning the values in the nid variable and then using the following variation of the Shell_NotifyIcon API call:

   Shell_NotifyIcon NIM_MODIFY, nid.

REFERENCES

For information regarding using the System Tray from Visual Basic 4.0 or earlier, please see the following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q149276
   TITLE     : HOWTO: Use Icons with the Windows 95 System Tray