Description
Returns the smallest available subscript for the indicated dimension of an array.
Syntax
LBound(arrayname[,dimension])
The LBound statement syntax has these parts:
|
Part |
Description |
|
arrayname |
Name of the array variable; follows standard variable naming conventions. |
|
dimension |
Whole number indicating which dimension's lower bound is returned. Use 1 for the first dimension, 2 for the second, and so on. If dimension is omitted, 1 is assumed. |
Remarks
The LBound function is used with the UBound function to determine the size of an array. Use the UBound function to find the upper limit of an array dimension.
LBound returns the values listed in the table below for an array with the following dimensions:
Dim A(1 To 100, 0 To 3, -3 To 4)
|
Statement |
Return Value |
|
LBound(A, 1) |
1 |
|
LBound(A, 2) |
0 |
|
LBound(A, 3) |
-3 |
The default lower bound for any dimension is either 0 or 1, depending on the setting of the Option Base statement.
Arrays for which dimensions are set using the To clause in a Dim, Private, Public, ReDim, or Static statement can have any integer value as a lower bound.
See Also
Dim Statement, Option Base Statement, Private Statement, Public Statement, ReDim Statement, Static Statement, UBound Function.
Example
This example uses the LBound function to determine the smallest available subscript for the indicated dimension of an array. Use the Option Base statement to override the default base array subscript value of 0.
Dim MyArray(1 To 10, 5 To 15, 10 To 20) ' Declare array variables.
Dim AnyArray(10)
Lower = LBound(MyArray, 1) ' Returns 1.
Lower = LBound(MyArray, 3) ' Returns 10.
Lower = LBound(AnyArray) ' Returns 0 or 1, depending on
' setting of Option Base.
This example writes the elements of the first custom list in column one on Sheet1.
Sub foo()
On Error GoTo err_handler
listArray = Application.GetCustomListContents(1)
For i = LBound(listArray, 1) To UBound(listArray, 1)
Worksheets("sheet1").Cells(i, 1).Value = listArray(i)
Next i
Exit Sub
err_handler:
MsgBox "Custom list does not exist"
End Sub
This example assumes that you used an external data source to create a PivotTable on Sheet1. The example inserts the SQL connection string and query string into a new worksheet.
Set newSheet = ActiveWorkbook.Worksheets.Add
sdArray = Worksheets("Sheet1").UsedRange.PivotTable.SourceData
For i = LBound(sdArray) To UBound(sdArray)
newSheet.Cells(i, 1) = sdArray(i)
Next i