Seek Statement

Description

Sets the position for the next read or write within a file opened using the Open statement.

Syntax

Seek [#]filenumber,position

The Seek statement syntax has these parts:

Remarks

Record numbers specified in Get and Put statements override file positioning done by Seek.

Performing a file write after doing a Seek operation beyond the end of a file extends the file. If you attempt a Seek operation to a negative or zero position, an error occurs.

See Also

Get Statement, Open Statement, Put Statement, Seek Function.

Example

This example uses the Seek statement to set the position for the next read or write within a file.

' For files opened in random-file mode, Seek sets the next 
' record. Assume TESTFILE is a file containing records of the
' user-defined type Record.
Type Record    ' Define user-defined type.
    ID As Integer
    Name As String * 20
End Type
Dim MyRecord As Record    ' Declare variable.
' Open file in random-file mode.
Open "TESTFILE" For Random As #1 Len = Len(MyRecord)
MaxSize = LOF(1) \ Len(MyRecord)    ' Get number of records in file.
' The loop reads all records starting from the last.
For RecordNumber = MaxSize To 1 Step - 1
    Seek #1, RecordNumber    ' Set position.
    Get #1, , MyRecord    ' Read record.
Next RecordNumber
Close #1    ' Close file.

' For files opened in modes other than random mode, Seek sets the 
' byte position at which the next operation will take place. Assume
' TESTFILE is a file containing a few lines of text.
Open "TESTFILE" For Input As #1    ' Open file for input.
MaxSize = LOF(1)    ' Get size of file in bytes.
' The loop reads all characters starting from the last.
For NextChar = MaxSize To 1 Step -1    
    Seek #1, NextChar    ' Set position.
    MyChar = Input(1,#1)    ' Read character.
Next NextChar
Close #1    ' Close file.