HyperlinkPart Function

Applies To

Application object.

Description

The HyperlinkPart function returns information about data stored as a Hyperlink data type. The data in a Hyperlink field can contain up to three parts in the following format:

displaytext#address#subaddress

Syntax

object.HyperlinkPart(hyperlink As Variant[, part As Integer])

The HyperlinkPart function has the following arguments.

Argument	Description

object	Optional. The Application object.
hyperlink	A Variant representing the data stored in a Hyperlink field.
part	Optional. The value for the part argument is an intrinsic constant representing the information you want returned by the HyperlinkPart function:

(continued)

Constant	Value	Description

acDisplayedValue	0	(Default) The underlined text displayed in a hyperlink.
acDisplayText	1	The displaytext part of a Hyperlink field.
acAddress	2	The address part of a Hyperlink field.
acSubAddress	3	The subaddress part of a Hyperlink field.

Remarks

You use the HyperlinkPart function to return one of three values from a Hyperlink field or the displayed value. The value returned depends on the setting of the part argument. The part argument is optional. If it's not used, the function returns the value Microsoft Access displays for the hyperlink (which corresponds to the acDisplayedValue setting for the part argument). The returned values can be one of the three parts of the Hyperlink field (displaytext, address, or subaddress) or the value Microsoft Access displays for the hyperlink.

Note If you use the HyperlinkPart function in a query, the part argument is required and you can't use the constants listed above but must use the actual value instead.

When a value is provided in the displaytext part of a Hyperlink field, the value displayed by Microsoft Access will be the same as the displaytext setting. When there's no value in the displaytext part of a Hyperlink field, the value displayed will be the address or subaddress part of the Hyperlink field, depending on which value is first present in the field.

The following table shows the values returned by the HyperlinkPart function for data stored in a Hyperlink field.

Hyperlink field data	HyperlinkPart function returned values

#http://www.microsoft.com#	acDisplayedValue: http://www.microsoft.com acDisplayText: acAddress: http://www.microsoft.com acSubAddress:
Microsoft#http://www.microsoft.com#	acDisplayedValue: Microsoft acDisplayText: Microsoft acAddress: http://www.microsoft.com acSubAddress:

(continued)

Hyperlink field data	HyperlinkPart function returned values

Customers##Form Customers	acDisplayedValue: Customers acDisplayText: Customers acAddress: acSubAddress: Form Customers
##Form Customers	acDisplayedValue: Form Customers acDisplayText: acAddress: acSubAddress: Form Customers

When you add an address part to a Hyperlink field by using the Insert Hyperlink dialog box (available by clicking Hyperlink on the Insert menu) or by typing an address part directly into a Hyperlink field, Microsoft Access adds the two # symbols that delimit parts of the hyperlink data.

You can add or edit the displaytext part of a hyperlink field by right-clicking a hyperlink in a table, pointing to Hyperlink on the shortcut menu, and then typing the display text in the Display Text box.

When you add data to a Hyperlink field directly or by using DAO methods, you must include the two # symbols to delimit the parts of the hyperlink data.

See Also

DataType property, FollowHyperlink method, Hyperlink property, HyperlinkAddress property, HyperlinkSubAddress property.

Example

The following example uses all four of the part argument constants to display information returned by the HyperlinkPart function for each record in a table containing a Hyperlink field. To try this example, paste the DisplayHyperlinkParts procedure into the Declarations section of a module. You can call the DisplayHyperlinkParts procedure from the Debug window, passing to it the name of a table containing hyperlinks and the name of the field containing Hyperlink data. For example:

DisplayHyperlinkParts "MyHyperlinkTableName", "MyHyperlinkFieldName"

Sub DisplayHyperlinkParts(strTable As String, strField As String)
    Dim dbs As Database, rst As Recordset
    Dim strMsg As String

    Set dbs = CurrentDb
    Set rst = dbs.OpenRecordset(strTable)

    While Not rst.EOF                    ' For each record in table.
        strMsg = "DisplayValue = " & HyperlinkPart(rst(strField), _
            acDisplayedValue) & vbCrLf & "DisplayText = " _
            & HyperlinkPart(rst(strField), acDisplayText) _
            & vbCrLf & "Address = " & HyperlinkPart(rst(strField), acAddress) _
            & vbCrLf & "SubAddress = " & HyperlinkPart(rst(strField), acSubAddress)
        ' Show parts returned by HyperlinkPart function.
        MsgBox strMsg
        rst.MoveNext
    Wend
End Sub

When you use the HyperlinkPart function in a query, the part argument is required. For example, the following SQL statement uses the HyperlinkPart function to return information about data stored as a Hyperlink data type in the URL field of the Links table:

SELECT Links.URL, HyperlinkPart([URL],0)
AS Display, HyperlinkPart([URL],1)
AS Name, HyperlinkPart([URL],2)
AS Addr, HyperlinkPart([URL],3) AS SubAddr
FROM Links;