Min, Max Functions

Description

Return the minimum or maximum of a set of values contained in a specified field on a query.

Syntax

Min(expr)

Max(expr)

The expr placeholder represents a string expression identifying the field that contains the data you want to evaluate or an expression that performs a calculation using the data in that field. Operands in expr can include the name of a table field, a constant, or a function (which can be either intrinsic or user-defined but not one of the other SQL aggregate functions).

Remarks

You can use Min and Max to determine the smallest and largest values in a field based on the specified aggregation, or grouping. For example, you could use these functions to return the lowest and highest freight cost. If there is no aggregation specified, then the entire table is used.

You can use Min and Max in a query expression and in the SQL property of a QueryDef object or when creating a Recordset object based on an SQL query.

See Also

QueryDef object ("DAO Language Reference"), SQL property ("DAO Language Reference").

Specifics (Microsoft Access)

In Microsoft Access, you can use the Min and Max functions in the query design grid, in an SQL statement in SQL view of the Query window, or in an SQL statement within Visual Basic code. You can also use the Min and Max functions in a calculated control on a form or report.

The Min and Max functions are most useful in totals queries and crosstab queries. They function the same way whether you create the query in the query design grid or as an SQL statement in SQL view.

In the query design grid, you can create a new totals query by clicking the Totals button on the Query Design toolbar. The Total row is then inserted in the grid. You can set the Total cell beneath a field to the aggregate function to perform on the data in that field.

For example, suppose you have an Orders table that has both a Freight field and a ShipCity field. You can create a query that displays the minimum freight cost for orders sent to each city. Create a new totals query, and drag the ShipCity field to the query design grid. The Total cell beneath the ShipCity field should be set to Group By. Drag the Freight field to the query design grid, and set the Total cell beneath it to Min. When you run the query, it will display the minimum freight cost for orders sent to each city.

You can view the SQL statement for this query by switching to SQL view. In this example, Microsoft Access creates the following SQL statement:

SELECT ShipCity, Min(Freight) AS MinOfFreight
FROM Orders GROUP BY ShipCity;

You can also use an SQL statement within Visual Basic code. For example, the following code creates a dynaset-type Recordset object from the preceding SQL statement:

Sub MinFreight()
    Dim dbs As Database, rst As Recordset, strSQL As String

    Set dbs = CurrentDb
    strSQL = "SELECT ShipCity, Min(Freight) AS MinOfFreight " _
        & "FROM Orders GROUP BY ShipCity;"
    Set rst = dbs.OpenRecordset(strSQL)
    rst.MoveLast
    Debug.Print rst.RecordCount
    Set dbs = Nothing
End Sub

To use the Min and Max functions in a calculated control, set the control's ControlSource property to an expression containing either of these functions. For example, to display the minimum freight cost for a set of orders in a text box, enter the following expression in the ControlSource property of the text box:

=Min([Freight])

If you use the Min or Max function in a calculated control, you can restrict the set of records against which the function is performed by setting the form's Filter property.

Example

This example uses the Orders table to return the lowest and highest freight charges for orders shipped to the United Kingdom.

This example calls the EnumFields procedure, which you can find in the SELECT statement example.

Sub MinMaxX()

    Dim dbs As Database, rst As Recordset

    ' Modify this line to include the path to Northwind
    ' on your computer.
    Set dbs = OpenDatabase("Northwind.mdb")

    ' Return the lowest and highest freight charges for
    ' orders shipped to the United Kingdom.
    Set rst = dbs.OpenRecordset("SELECT " _
        & "Min(Freight) AS [Low Freight], " _
        & "Max(Freight) AS [High Freight] " _
        & "FROM Orders WHERE ShipCountry = 'UK';")

    ' Populate the Recordset.
    rst.MoveLast

    ' Call EnumFields to print the contents of the
    ' Recordset. Pass the Recordset object and desired
    ' field width.
    EnumFields rst, 12

    dbs.Close

End Sub

Example (Microsoft Access)

The following example assumes that you have an Orders table that contains fields called Freight and ShipCountry. You can use the Min and Max functions to return the lowest and highest freight charges for orders shipped to the United Kingdom. Enter the following expressions in SQL view in the Query window:

SELECT Min([Freight]) AS [LowFreight] FROM Orders WHERE [ShipCountry] = 'UK';

SELECT Max([Freight]) AS [HighFreight] FROM Orders WHERE [ShipCountry] = 'UK';

The next example creates a calculated control that displays the lowest freight charge for all records in the same Orders table. Open a new form and set its RecordSource property to Orders. Enter the following expression in the ControlSource property of a text box on the form. To apply a condition that limits the search to only some records, such as those for orders shipped to the United Kingdom, set the form's Filter property.

=Min([Freight])