Retrieving Properties

To identify the properties associated with an object, you write code to iterate through the object’s Properties collection, retrieving the information you want. Some special cases when referencing properties may be problematic:

• Some properties are not readable. The Password property of the User object is a good example. You can set the value of the property through code, but you can’t retrieve the value. (If you could, it would be an obvious hole in the Microsoft Jet security model.)
  
  
• Some properties are readable at some times, but not at others. For example, you can’t read the Value property of a Field object in a recordset if there is no current record in the recordset.
  
  
• Certain properties that you are explicitly looking for may not exist. For example, if you’re using Microsoft Access, you may have code that retrieves the Description property of a TableDef object. However, unless you explicitly add a description to the table through the Microsoft Access user interface or through DAO code, this user-defined property doesn’t exist, and a run-time error occurs when the code executes.

The following code displays each of the properties of each User object in the current Workspace. After it has tried to retrieve the property value, it checks to see if an error has occurred, and if so, checks the specific error number. If the error is anticipated, as in the case of trying to retrieve a write-only property (error 3251), error text is printed. If the error isn’t anticipated, the code displays a message to the user.

Dim usr As User
Dim prp As Property
Dim varValue As Variant

For Each usr In Workspaces(0).Users
	For Each prp In usr.Properties
		' Disable error handling.
		On Error Resume Next
		varValue = prp.Value
		' See if an error occurred.
		Select Case Err
			Case 3251				' Operation not supported error.
				Debug.Print prp.Name & ": <Error " & Err _
					& ": " & Err.Description & ">"
			Case 0					' No error.
				Debug.Print prp.Name & ": " & varValue
			Case Else				' Unanticipated error.
				MsgBox "Error: " & Err & vbCrLf & Err.Description
		End Select
		Err.Clear
		' Re-enable error handling.
		On Error GoTo 0
	Next prp 
	Debug.Print
Next usr