Sending a Meeting Request

[This is preliminary documentation and subject to change.]

A meeting request is a message sent by the meeting organizer to the attendees to invite them to a meeting. A meeting request contains a description of the meeting, including the starting time, ending time, and location. CDO creates a meeting request using the IAppointment.CreateRequest method.

To send a meeting request

1. Create an Appointment object and set its properties. A StartTime and either an EndTime or a Duration are required.
2. Create a Configuration object.
3. Set the configuration fields and then set the Configuration object in the Appointment object.
4. Add attendees to the meeting request by adding Attendee objects to the Attendees collection.
5. Create a Calendar Message object using the CreateRequest method.
6. Send the message.
7. Save the Appointment to the organizer's calendar (optional).

In the following code example, a specific user creates a meeting request and sends it to another user. It saves the meeting in the organizer's calendar.

Dim iAppt       As New Appointment
Dim iCalMsg     As CalendarMessage
Dim Config      As New Configuration
Dim iAttendee   As New Attendee
Dim CalendarURL As String

CalendarURL = "file://./backofficestorage/" & DomainName & "/MBX/" & UserName & "/calendar/"

'Set the configuration fields
Config.Fields(cdoSendEmailAddress) = UserName & "@" & DomainName
Config.Fields.Update
iAppt.Configuration = Config

'Set the appointment properties
iAppt.StartTime = #10/13/1999 12:30:00 PM#
iAppt.EndTime = #10/13/1999 1:30:00 PM#
iAppt.Subject = "Lunch meeting"
iAppt.Location = "Building B Cafeteria"

'Add an attendee
Set iAttendee = iAppt.Attendees.Add
iAttendee.Address = "someone@" & DomainName
iAttendee.Role = cdoRequiredParticipant

'Create the calendar message and send it
Set iCalMsg = iAppt.CreateRequest
iCalMsg.Message.Send

'Save the appointment to the organizer's calendar
iAppt.DataSource.SaveToContainer CalendarURL

Note   By default, calendar messages are sent using the Simple Mail Transfer Protocol (SMTP) pickup directory.