In order for your logging module to be available through the IIS administrative user interface, you should add it to the /LM/LOGGING path of the metabase. You should give the key the same name as the custom logging module, and it should contain two values: LogModuleId and LogModuleUiId. LogModuleId should contain a string that represents the custom module's GUID, and LogModuleUiId should contain a string that represents the GUID of the custom module's user interface.
If you use a script to add a logging module to the /LM/LOGGING path, you should add the GUID for the log module to the LogModuleList Automation property.
The following script demonstrates how to add a custom logging module:
Dim oWebInfo, oLogging, oNewLogMod
Dim strNewModName, strModId, strModUiId
' sample name and UUIDs (note: UUIDs given here are from ODBC Logging module)
' ****INSERT REAL NAME AND UUIDS HERE***
strNewModName = "My New Logging Module"
strModId = "{FF16065B-DE82-11CF-BC0A-00AA006111E0}"
strModUiId = "{31DCAB86-BB3E-11D0-9299-00C04FB6678B}"
' Create a new logging module node in the master logging tree, with the name specified by strNewModName
Set oLogging = GetObject( "IIS://Localhost/Logging" )
Set oNewLogMod = oLogging.Create( "IIsLogModule", strNewModName )
' Set configuration settings for new module
oNewLogMod.LogModuleId = strModId
oNewLogMod.LogModuleUiId = strModUiId
' Make sure the properties get written back to the object from the ADSI property cache
oNewLogMod.SetInfo
' Finally, add new logging module to the list of available logging modules
Set oWebInfo = GetObject( "IIS://Localhost/W3SVC/Info" )
oWebInfo.LogModuleList = oWebInfo.LogModuleList & "," & strNewModName
' Again, write property back to object from property cache
oWebInfo.SetInfo
For more information on using scripts to administer IIS, see Using IIS Admin Objects.
Note The logging module must be resident and registered on the server machine.