How to Change Background Sounds Randomly Using ASP

ID: Q248027

The information in this article applies to:

Microsoft Internet Information Server 4.0
Microsoft Internet Information Services version 5.0

SUMMARY

This articles describes a process of returning a random background sound from a folder in your Web site using Microsoft Active Server Pages (ASP) and the Scripting.FileSystemObject.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Solution Provider or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Solution Providers, please see the following page on the World Wide Web:

http://www.microsoft.com/mcsp/

For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

Random Sounds from ASP

Use the following steps to create an include file for use with ASP containing a function named RandomSound(). This function randomly returns the name of a sound based on the contents in a folder, which is passed by name to the function, or the name of a default sound if no sound files are found in the folder.

Create a folder named "Sounds" in your Web site's root folder.

Copy a few .wav, .mid, or .rmi sound files into the Sounds folder. (There are usually several in the %WINDIR%\Media folder.)

Save the following ASP page as "RandomTest.asp" in your Web site's root folder:
```
<% @Language="VBScript" %>
<% Option Explicit %>
<html>
<head>

<bgcound src="<%=RandomSound("/sounds/","/sounds/default.mid")%>">
</head>
<body>
<h2 align="center">Random Background Sound Test</h2>
<p>Hit "Refresh" in your browser to change sounds.</p>
</body>
</html> 
```
Note: The call to the RandomSound() function passes the name of the default sound as /Sounds/Default.mid. You will need to change that to a valid sound file name and path when you want the function to a return default sound when a folder contains no sound files.

Create a folder named "Includes" in your Web site's root directory.

Save the following ASP code in the Includes folder as RandomSound.inc:


<%
  Function RandomSound(strPath,strDefault)
    On Error Resume Next
    Randomize Timer

    ' declare all variables
    Dim objFSO, objFolder, objFiles, objFile
    Dim strFiles, strSound, strPhysical, strFile

    ' this constant has the names of valid file extensions
    ' it can be customized for more or less file types
    Const strValid = ".wav.mid.rmi"

    ' make sure we have a trailing slash in the path
    If Right(strPath,1) <> Chr(47) Then strPath = strPath & Chr(47)
    ' get the physical path of the folder
    strPhysical = Server.MapPath(strPath)
    ' get a File System Object
    Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
    ' create a folder object
    Set objFolder = objFSO.GetFolder(strPhysical)
    ' get the files collection
    Set objFiles = objFolder.Files

    ' enumerate the files collection looking for valid files
    For Each objFile in objFiles
      strFile = LCase(objFile.Name)
      If Instr(strValid,Right(strFile,4)) Then
        ' add valid files to a string of file names
        strFiles = strFiles & strFile & vbTab
      End If
    Next

    ' split the names into an array
    strSound = Split(strFiles,vbTab)
    
    ' if we have an array...
    If UBound(strSound) > 1 Then
      ' get a random name
      RandomSound = strPath & strSound(Int(Rnd(1)*UBound(strSound)))
    Else
      ' otherwise return the default
      RandomSound = strDefault
    End If

  End Function
%>

When you browse the RandomTest.asp page on a computer equipped with a sound card installed you should hear a random background sound file being played. As long as valid files are found in the Sounds folder the background sound should change each time you refresh the page.

More information on Microsoft's scripting technologies can be found at http://msdn.microsoft.com/scripting/.

Additional query words:

Keywords :
Version : winnt:4.0,5.0
Platform : winnt
Issue type : kbhowto