XL: Visual Basic Function to Format Complex Numbers

ID: Q151338

The information in this article applies to:

Microsoft Excel 98 Macintosh Edition
Microsoft Excel 97 for Windows
Microsoft Excel for Windows 95, versions 7.0, 7.0a
Microsoft Excel for Windows NT, version 5.0
Microsoft Excel for Windows, versions 5.0, 5.0c
Microsoft Excel for the Macintosh, versions 5.0, 5.0a

SUMMARY

Because Microsoft Excel stores complex numbers as text, complex numbers cannot be formatted like real numbers. This article provides sample code for a user-defined function that applies number formats to complex numbers.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

Complex numbers are real and imaginary coefficients which combine to form a complex number. They are in the form of x+yi or x+yj where x is the real coefficient and y is the imaginary coefficient. Complex numbers always carry a suffix of the letter i or j.

The function in this article takes three arguments: the number to be formatted, a format code for the real component, and a format code for the imaginary component. For example, the function


   =FormatComplex(A1,"0.00","0.0000")

would display the complex number in cell A1 with two decimal places for the real component and four decimal places for the imaginary component.

You can also use multisection formats to format positive, negative, and zero components differently. For example, the function


   =FormatComplex(A1,"0.00;-0.00;0","0.0000;-0.0000;0")

would have the same result as the earlier example, but with zero components displaying as "0" rather than including extra zeroes to the right of the decimal point. If you use a multisection format, the formats for negative numbers must begin with a "-" (minus sign) as in the example.

Sample Visual Basic Procedure


   Option Explicit

   Function FormatComplex(NumToFormat As String, RealFormatCode As _
       String, ImagFormatCode As String)

       Dim PlusOrMinus As String
       Dim CharPosition As Integer

       ' Is NumToFormat real?
       If Right(NumToFormat, 1) <> "i" Then

           ' NumToFormat is real.
           FormatComplex = Format(NumToFormat, RealFormatCode)
       Else

           ' NumToFormat is either imaginary or complex.
           ' Search NumToFormat from right until + or - or left end is
           ' reached.
           PlusOrMinus = "not found"
           For CharPosition = Len(NumToFormat) - 1 To 1 Step -1
               PlusOrMinus = Mid(NumToFormat, CharPosition, 1)
               If PlusOrMinus = "+" Or PlusOrMinus = "-" Then Exit For
           Next

           ' Is NumToFormat complex or imaginary?
           If (PlusOrMinus = "+" Or PlusOrMinus = "-") And _
               CharPosition <> 1 Then

               ' NumToFormat is complex.
               ' Is imaginary component negative?
               If Mid(NumToFormat, CharPosition, _
                   Len(NumToFormat) - CharPosition) < 0 Then

                   ' Imaginary component is negative, so "-" does not need
                   ' to be added.
                   FormatComplex = Format(Left(NumToFormat, _
                       CharPosition - 1), RealFormatCode) & _
                       Format(Mid(NumToFormat, CharPosition, _
                       Len(NumToFormat) - CharPosition), _
                       ImagFormatCode) & "i"
               Else

                   ' Imaginary component is not negative, so "+" needs to
                   ' be added.
                   FormatComplex = Format(Left(NumToFormat, _
                       CharPosition - 1), RealFormatCode) & "+" & _
                       Format(Mid(NumToFormat, CharPosition, _
                       Len(NumToFormat) - CharPosition), _
                       ImagFormatCode) & "i"
               End If
           Else

               ' NumToFormat is imaginary.
               FormatComplex = Format(Left(NumToFormat, _
                   Len(NumToFormat) - 1), ImagFormatCode) & "i"
           End If

       End If

   End Function

Additional query words: 5.00a 5.00c 8.00 XL98 XL97 XL7 XL5

Keywords : kbprg kbdta kbdtacode PgmHowto KbVBA
Version : MACINTOSH:5.0,5.0a,98; WINDOWS:5.0,5.0c,7.0,7.0a,97; winnt:5.0
Platform : MACINTOSH WINDOWS winnt
Issue type : kbhowto