WD2000: Macro to Find Automatic (Soft) Page Breaks

ID: Q201953

The information in this article applies to:

Microsoft Word 2000

SUMMARY

To search for "hard" (manually inserted) page breaks and section breaks in a Word document, click Find on the Edit menu, and type ^m in the Find what box.

There is no search character to locate "soft" (automatic) page breaks within a document. The macro samples in the "More Information" section of this article can be used to locate automatic page breaks.

MORE INFORMATION

Word automatically inserts soft page breaks when the end of the document page is reached. Any new text is automatically pushed to the next page. A soft page break also occurs before a paragraph formatted with the Page Break Before option selected (on the Format menu, click Paragraph, click the Line and Page Breaks tab, and then select the Page Break Before check box).

You can insert hard page breaks by pressing CTRL+ENTER or selecting the Page break button (on the Insert menu, click Break, and then select Page break).

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Solution Provider or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Solution Providers, please see the following page on the World Wide Web:

http://www.microsoft.com/mcsp/

For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

The following macro samples examine the page breaks in a document and determine whether they are soft page breaks. The macro samples retrieve the total number of pages in the document and then move to each page break successively. By moving the selection to the left one character, the macro samples determine whether the new selection is text or a hard page break. Document text has a character code greater than 31, and a hard page break is character number 12 or 14.


Sub FindSoftPageBreaks()

   Dim iPgNum As Integer
   Dim sPgNum As String
   Dim ascChar As Integer

   ' Set bookmark for return.
   ActiveDocument.Bookmarks.Add Name:="WhereYouWere", _
      Range:=Selection.Range

   ' Go to start of document.
   Selection.HomeKey Unit:=wdStory, Extend:=wdMove

   ' Repaginate the document.
   ActiveDocument.Repaginate

   ' Loop through the number of pages in the document.
   For iPgNum = 2 To Selection.Information(wdNumberOfPagesInDocument)
      sPgNum = CStr(iPgNum)

      ' Go to next page in iteration.
      Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, _
         Count:=sPgNum

      ' Move insertion point left one character.
      Selection.MoveLeft Unit:=wdCharacter, Count:=1, Extend:=wdMove

      ' Retrieve the character code at insertion point.
      ascChar = Asc(Selection.Text)

      ' Check the character code for hard page break or text.
      If ascChar <> 12 And ascChar <> 14 Or ascChar > 31 Then
         MsgBox "An automatic page break precedes page " + sPgNum + "."
      End If
   Next

   ' Return to starting location.
   Selection.GoTo What:=wdGoToBookmark, Name:="WhereYouWere"

   ' Delete the return marker.
   ActiveDocument.Bookmarks("WhereYouWere").Delete

End Sub

To replace soft page breaks with hard page breaks throughout your document, replace this line of code:


  MsgBox "An automatic page break precedes page " + sPgNum + "."

with the following lines:


' Check to see if the insertion point is in a table.
x = Selection.Information(wdWithInTable)
If x then

   ' Move insertion point out of table.
   Selection.MoveRight Unit:=wdCharacter, Count:=1, Extend:=wdMove

End If

Selection.InsertBreak Type:=wdPageBreak

REFERENCES

For more information about using the sample code in this article, click the article number below to view the article in the Microsoft Knowledge Base:

Q212536 OFF2000: How to Run Sample Code from Knowledge Base Articles

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

Q226118 OFF2000: Programming Resources for Visual Basic for Applications

Additional query words: wordcon vb

Keywords : kbdta kbdtacode OffVBA kbmacroexample kbwordvba wd2000
Version : WINDOWS:2000
Platform : WINDOWS
Issue type : kbhowto