PPT2000: Sample Visual Basic Code for Moving Objects On Screen During a Slide Show

ID: Q222764

The information in this article applies to:

Microsoft PowerPoint 2000

SUMMARY

This article contains a sample Microsoft Visual Basic for Applications macro (Sub procedure) that animates a small shape bouncing off the sides of the screen during a slide show. This animation is started by creating an action button linked to the macro BouncingBox. It works best if there are no other animated objects on your slide.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft Support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

NOTE: The following macro examples only work from within the PowerPoint application. Visual Basic for Applications macros are not supported by the Microsoft PowerPoint Viewer. For additional information, please see the following article in the Microsoft Knowledge Base:

Q230746 PPT: Viewer: Presentation Macros Don't Run

This macro assumes that you have linked the macro code to an action setting, either to an action button or an object on the slide. To start the macro, click on the linked button or object.

For more information about linking macros to action controls, ask the Office Assistant How do I Set up a macro to run during a slide show.

Sample Visual Basic Procedure


   Sub BouncingBox()

      ' Change this constant to vary the speed of movement.
      Const Bounce As Integer = 60

      ' These constants determine the boundaries for the slide show. They
      ' are in points, 72 points to the inch, so a standard slide, which is
      ' 7.5" tall by 10" wide, would be 540 x 720. The object being
      ' animated is 40 points tall and 40 points wide. This amount is
      ' subtracted from the constants to prevent the object from leaving
      ' the slide area.
      Const sHght As Integer = 500
      Const sWdth As Integer = 680

      ' Provide a handle to the active slide show window.
      Dim show as SlideShowWindow
      Dim BounceBox as Shape

      ' Assign the current running slideshow to show.
      Set show = ActivePresentation.SlideShowWindow

      ' Assign BounceBox to the second object shape on slide 1.
      Set BounceBox = ActivePresentation.Slides(1).Shapes(2)

      ' This loop moves the BounceBox object up and to the left until
      ' either the top or the left hand side is reached. The object moves
      ' on a diagonal, 45-degree line.
      '
      ' A note about coordinates. 0,0 is the upper left hand corner of the
      ' slide. 720,540 is the lower right hand corner of the slide. To move
      ' the BounceBox up and to the left, you must decrement its X,Y
      ' values.
      While BounceBox.Top > 0 And BounceBox.Left > 0
         BounceBox.IncrementTop -Bounce
         BounceBox.IncrementLeft -Bounce
         show.View.GotoSlide 1
      Wend

      ' This loop moves the BounceBox down to the left by the Bounce value.
      While BounceBox.Top < sHght And BounceBox.Left > 0
         BounceBox.IncrementTop Bounce
         BounceBox.IncrementLeft -Bounce
         show.View.GotoSlide 1
      Wend

      ' This loop moves the BounceBox down to the right by the Bounce
      ' value.
      While BounceBox.Top < sHght And BounceBox.Left < sWdth
         BounceBox.IncrementTop Bounce
         BounceBox.IncrementLeft Bounce
         show.View.GotoSlide 1
      Wend

      ' This loop moves the BounceBox up to the right by the Bounce value.
      While BounceBox.Top > 0 And BounceBox.Left < sWdth
         BounceBox.IncrementTop -Bounce
         BounceBox.IncrementLeft Bounce
         show.View.GotoSlide 1
      Wend

   End Sub

REFERENCES

For more information about using the sample code in this article, please see the following article in the Microsoft Knowledge Base:

Q212536 OFF2000: How to Run Sample Code from Knowledge Base Articles

Additional query words: 9.00 ppt9 vba vbe ppt2k powerpt vba2k ppt9.0 ppt2000 program programming

Keywords : kbcode kbmacro kbprg kbdta kbdtacode kbpptvba
Version : WINDOWS:2000
Platform : WINDOWS
Issue type : kbhowto