PPT2000: Sample Code to Rotate 3D Shapes During a Slide Show

ID: Q222766

The information in this article applies to:

Microsoft PowerPoint 2000

SUMMARY

The following macro code enables you to have a three-dimensional (3-D) shape rotate along the X and Y axes during a slide show. This animation is started by creating an action button linked to the macro Rotate3d_Object.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft Support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

NOTE: The following macro examples only work from within the PowerPoint application. Visual Basic for Applications macros are not supported by the Microsoft PowerPoint Viewer. For additional information, please see the following article in the Microsoft Knowledge Base:

Q230746 PPT: Viewer: Presentation Macros Don't Run

This macro assumes that you have linked the macro code to an action setting, either to an action button or an object on the slide itself. To start the macro, click on the linked button or object.

For more information about linking macros to action controls, ask the Microsoft PowerPoint Office Assistant How do I Set up a macro to run during a slide show.

Sample Visual Basic Procedure


   Sub Rotate3d_Object()

      ' Change this constant for different degrees or rotation.
      Const Increment As Integer = 5

      ' Use to control the for loop.
      Dim i As Integer
      Dim j As Integer

      ' A handle used to control the shape.
      Dim FirstShape As Shape

      ' A handle to reference the slide show window.
      Dim show as SlideShowWindow

      ' Two methods to set the active SlideShowWindow to the variable show:
      ' Set show = ActivePresentation.SlideShowSettings.Run
      ' -or-
      Set show = ActivePresentation.SlideShowWindow

      ' The first method allows you either to start the macro, which then
      ' automatically runs the slide show and the animations, or to link
      ' the macro to an object on the slide via an action setting. The
      ' animations would then run by clicking the object during a slide
      ' show. The second method is strictly an action setting, and
      ' functions only during a slide show.

      ' Get a reference to the shape. This assumes that the 3-D shape is in
      ' index position 2 on slide 1 of the presentation. That is, it is
      ' the second shape on the slide.
      Set FirstShape = ActivePresentation.Slides(1).Shapes(2)

      ' The RotationY and RotationX commands can rotate an object only
      ' from -90 degrees to 90 degrees. Also, it rotates to a specific
      ' point on a compass: if you rotate along the y axis to 45 degrees,
      ' the shape is now 45 degrees from dead center.
      For i = -45 To 45 Step Increment

         ' Rotate the shape to the degree specified.
         FirstShape.ThreeD.RotationY = i
         FirstShape.ThreeD.RotationX = i

         ' Refresh the slide. This step is needed to redraw the screen
         ' after the rotation step; Otherwise, the animation effect is
         ' invisible.
         show.View.GotoSlide 1

      Next i

      For i = 45 To -45 Step -Increment

         FirstShape.ThreeD.RotationY = i
         FirstShape.ThreeD.RotationX = i

         ' Refresh the slide.
         show.View.GotoSlide 1
      Next i

   End Sub

REFERENCES

For more information about using the sample code in this article, please see the following article in the Microsoft Knowledge Base:

Q212536 OFF2000: How to Run Sample Code from Knowledge Base Articles

Additional query words: 9.00 ppt9 vba vbe ppt2k powerpt vba2k ppt9.0 ppt2000 program programming

Keywords : kbcode kbmacro kbprg kbdta kbdtacode kbpptvba
Version : WINDOWS:2000
Platform : WINDOWS
Issue type : kbhowto