PPT2000: Sample Code to Create a Basic Organization Chart

• Microsoft PowerPoint 2000

SUMMARY

This article contains a sample Microsoft Visual Basic for Applications macro (Sub procedure) that creates a new slide in the active presentation and then adds four boxes. The boxes appear on the slide in a layout similar to the Organization Chart AutoLayout.

The boxes the macro creates are not Organization Chart objects. The boxes are PowerPoint objects. You can use the PowerPoint drawing tools to edit these boxes.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft Support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

Q230746 PPT: Viewer: Presentation Macros Don't Run

Sample Visual Basic Procedure

   Sub CreateOrgChart()

      ' Define the varables used for the boxes.
      Dim Main As Shape
      Dim MBox As Shape
      Dim LBox as Shape
      Dim RBox as Shape

      ' Change these values to make different size boxes.
      Const BoxWidth As Integer = 200
      Const BoxHeight As Integer = 75

      ' Change this value to change the space between boxes.
      Const space As Integer = 40

      ' Declare variables to hold slide height and width info.
      Dim h As Integer
      Dim w As Integer
      Dim TopBox As Integer
      Dim left As Integer
      Dim Level2 As Integer

      ' Holds an object reference to a slide.
      Dim TheSlide As Slide

      ' Create a new slide.
      Set TheSlide = ActivePresentation.Slides.Add(1, ppLayoutTitleOnly)

      ' Switch the presentation to slide view.
      With ActiveWindow
         If .ViewType <> ppViewSlide Then .ViewType = ppViewSlide
      End With

      ' Get the height and width of the slide.
      With ActiveWindow.Presentation.PageSetup
         h = .SlideHeight
         w = .SlideWidth
      End With

      ' Make sure height and width are valid.
      If h = 0 Or w = 0 Then
         ' The Height and Width are invalid
         MsgBox "Something is wrong!" _
            & " Try restarting your computer.", vbCritical
         End
      End If

      ' Set up parameters for the add shape method.
      left = ((w / 2) - (BoxWidth / 2))
      TopBox = ((h / 2) - (BoxHeight))
      Level2 = (TopBox + BoxHeight + space)

      ' Add the Organization Chart Boxes.
      With ActiveWindow.Selection.SlideRange.Shapes
         Set Main = .AddShape(msoShapeRectangle, _
                          left, _
                          TopBox, _
                          BoxWidth, _
                          BoxHeight)
         Set MBox = .AddShape(msoShapeRectangle, _
                           left, _
                           Level2, _
                           BoxWidth, _
                           BoxHeight)
         Set LBox = .AddShape(msoShapeRectangle, _
                           (left - space - BoxWidth), _
                           Level2, _
                           BoxWidth, _
                           BoxHeight)
         Set RBox = .AddShape(msoShapeRectangle, _
                           (left + space + BoxWidth), _
                           Level2, _
                           BoxWidth, _
                           BoxHeight)
      End With

      ' Use a connector to conncect the first box and third box.
      With ActiveWindow.Selection.SlideRange.Shapes.AddConnector _
            (msoConnectorElbow, 0, 0, 100, 100).ConnectorFormat
         .BeginConnect ConnectedShape:=LBox, ConnectionSite:=1
         .EndConnect ConnectedShape:=RBox, ConnectionSite:=1
      End With

      ' Use a connector to connect the top box to the middle box.
      With ActiveWindow.Selection.SlideRange.Shapes.AddConnector _
            (msoConnectorElbow, 0, 0, 100, 100).ConnectorFormat
         .BeginConnect ConnectedShape:=Main, ConnectionSite:=3
         .EndConnect ConnectedShape:=MBox, ConnectionSite:=1
      End With

   End Sub 

REFERENCES

For more information about using the sample code in this article, please see the following article in the Microsoft Knowledge Base:

Q212536 OFF2000: How to Run Sample Code from Knowledge Base Articles

Additional query words: 9.00 ppt9 vba vbe ppt2k powerpt vba2k ppt9.0 ppt2000 program programming

Keywords : kbcode kbmacro kbprg kbdta kbdtacode kbpptvba
Version : WINDOWS:2000
Platform : WINDOWS
Issue type : kbhowto