XL97: How to Programmatically Perform a Web Query

ID: Q162080

The information in this article applies to:

Microsoft Excel 97 for Windows

SUMMARY

A Web query is a new feature in Microsoft Excel 97 that allows you to retrieve data stored on an intranet, the Internet, or the World Wide Web. A Web query can use static parameters, dynamic parameters, or a combination of both. Queries with static parameters send a query without any input; queries with dynamic parameters prompt you for input. Regardless of the type of parameters in the query, the requested information is pulled from an Internet or an intranet site, and the results are placed in a worksheet.

Using a Hypertext Markup Language (HTML) form, you can use two methods to send parameters to the server: GET and POST. Use GET when you are sending small amounts of information and POST when you are sending larger amounts of information. The GET method appends the parameters to the Uniform Resource Locator (URL). The POST method sends the parameters as a separate line of text in the query file.

This article provides example macros that run Web queries that use both the GET and the POST methods.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

Programmatically Running a Web Query

In order to programmatically run a Web query, you must use the Add method of the QueryTables collection. When you use the Add method, it returns a QueryTable object that represents the new query table. The syntax for the Add method is as follows:


   <expression>.Add(Connection, Destination, Sql)

where <expression> is required and returns a QueryTable object. The Connection argument is also required and is the data source for the query table. In the context of Web queries, you can use one of two types of Connection strings: URL or FINDER. When you specify the URL type, you use the complete URL to the server on which you are performing the query (you can copy the third line from any Web query (.iqy) file and use it as the URL). When you specify the FINDER type, you use the complete path to an existing Web query (.iqy) file.

Creating a Visual Basic Module

Before you use the examples in this article, you must create a module. To do this, use the following steps:

Save and close any open workbooks, and then create a new workbook.

Start the Visual Basic Editor (press ALT+F11).

On the Insert menu, click Module.

URL Examples

Static Web Query (GET Method):

The following example uses static parameters; you are not prompted for the values to send to the server. To create this macro, use the following steps:

In the module, type the following code:


     Sub URL_Get_Query()

          With ActiveSheet.QueryTables.Add(Connection:= _
              "URL;http://webservices.pcquote.com/cgi-" & _
              "bin/excelget.exe?TICKER=msft", _
              Destination:=Range("a1"))

              .BackgroundQuery = True
              .TablesOnlyFromHTML = True
              .Refresh BackgroundQuery:=False
              .SaveData = True
          End With
      End Sub

Switch to Sheet1 in the workbook.

Run the URL_Get_Query macro.

A detailed stock quote for MSFT is returned to Sheet1.

Dynamic Web Query (POST Method):

The following example uses dynamic parameters; you are prompted for the values to send to the server. This example uses the POST method because the parameters are contained in the query. To create the macro, use the following steps:

Switch to the Visual Basic Editor and type the following macro in the module sheet:


 Sub URL_Post_Query()

          With ActiveSheet.QueryTables.Add(Connection:= _
              "URL;http://webservices.pcquote.com/cgi-bin/excel.exe", _
              Destination:=Range("a1"))

              .PostText = _
                  "QUOTE0=[""QUOTE0"",""Enter up to 20 symbols separated "
& _
                  "by spaces.""]"

              .BackgroundQuery = True
              .TablesOnlyFromHTML = True
              .Refresh BackgroundQuery:=False
              .SaveData = True
          End With
      End Sub

Switch to Sheet2 in the workbook and run the URL_Post_Query macro.

Because this example uses dynamic parameters, are prompted for the parameter values.

In the Enter Parameter Value dialog box, type up to twenty valid stock symbols that are separated by a space; for example, type msft.

Click OK.

The stock quotes for the stock symbols you entered are returned to a table in Sheet2.

FINDER Examples

Dynamic Query (GET Method):

With the FINDER type of connection, specify the full path to an existing Web query (.iqy) file. This example uses the GET method because the Web query file, "Detailed Stock Quote by PC Quote, Inc.iqy," uses the GET method. That is, the parameters and the URL of the server are on the third line in the file. To create the macro, use the following steps:

Switch to the Visual Basic Editor and type the following macro in the module sheet:


      Sub Finder_Get_Query()

          IQYFile = "c:\Program Files\Microsoft Office\Queries\" & _
              "Detailed Stock Quote by PC Quote, Inc.iqy"

          With ActiveSheet.QueryTables.Add(Connection:= _
              "FINDER;" & IQYFile, Destination:=Range("A1"))

              .BackgroundQuery = True
              .TablesOnlyFromHTML = True
              .Refresh BackgroundQuery:=False
              .SaveData = True
          End With
      End Sub

Switch to Sheet3 in the workbook and run the Finder_Get_Query macro.

Because this example uses a dynamic parameter, you are prompted for the parameter value.

In the Enter Parameter Value dialog box, type a valid stock symbol.

Click OK.

A detailed stock quote is returned to Sheet3 for the stock symbol you entered in Step 3.

Dynamic Query (POST Method):

With the FINDER type of connection, specify the full path to an existing Web query (.iqy) file. This example uses the POST method because the Web query file, "Multiple Stock Quotes by PC Quote, Inc.iqy," uses the POST method. That is, the parameters are on the fourth line, and the URL of the server is on the third line in the file. To create the macro, use the following steps:

Switch to the Visual Basic Editor and type the following macro in the module sheet:


   Sub Finder_Post_Query()

          IQYFile = "c:\program files\microsoft office\queries\" & _
              "Multiple Stock Quotes by PC Quote, Inc.iqy"

          With ActiveSheet.QueryTables.Add(Connection:= _
              "FINDER;" & IQYFile, Destination:=Range("A1"))

              .PostText = _
                  "QUOTE0=[""QUOTE0"",""Enter up to 20 symbols separated "
& _
                  "by spaces.""]"

              .BackgroundQuery = True
              .TablesOnlyFromHTML = True
              .Refresh BackgroundQuery:=False
              .SaveData = True
          End With
      End Sub

Switch to Sheet4 in the workbook and run the Finder_Post_Query macro.

Because this example uses dynamic parameters, you are prompted for the parameter values.

In the Enter Parameter Value dialog box, type up to twenty valid stock symbols that are separated by a space; for example, type msft.

Click OK.

The stock quotes for the stock symbols you entered are returned to a table in Sheet4.

For additional information, please see the following article in the Microsoft Knowledge Base:

Q157482 XL97: How to Create Web Query (.iqy) Files

REFERENCES

For more information about Web queries, click the Index tab in Microsoft Excel Help, type the following text

web, queries

and then double-click the selected text to go to the "Create a Web query" topic.

For more information about the Add Method, click the Office Assistant, type querytable, click Search, and then click to view "Add Method (QueryTables Collection)".

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If <Product> Help is not installed on your computer, please see the following article in the Microsoft Knowledge Base:

Q120802 Office: How to Add/Remove a Single Office Program or Component

Additional query words: 97 XL97

Keywords : kbprg kbualink97 kbdta kbdtacode xlquery KbVBA
Version : WINDOWS:97
Platform : WINDOWS
Issue type :