XL98: How to Trap Events for an Embedded Chart

• Microsoft Excel 98 Macintosh Edition

SUMMARY

In Microsoft Excel 98, you can associate a chart sheet in a workbook with a Visual Basic module. This means that you can create a macro that runs when certain events occur on the chart sheet. However, this functionality does not apply to charts that are embedded on a worksheet.

This article contains sample macros that trap an event for an embedded chart.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

Setting Up a Sample Embedded Chart

1. Save and close any open workbooks, and then create a new workbook.



2. Type the following data in Sheet1:

   A1: 1
   A2: 2
   A3: 3




3. Select the range A1:A3. On the Insert menu, click Chart.



4. In the "Chart Wizard - Step 1 of 4 - Chart Type" dialog box, and click Finish.

Writing the Macro Code

1. Start the Visual Basic Editor by pressing OPTION+F11.



2. On the Insert menu, click Class Module.
   
   This step inserts a class module called Class1 into your project.



3. In this class module, type the following code:

   
          Public WithEvents EmbChart As Chart 

   The WithEvents keyword makes the EmbChart variable available in the Object list in the Class1 (Code) module window.



4. In the Class1 (Code) window, click EmbChart in the Object list.
   
   The following code automatically appears in the class module:

   
          Private Sub EmbChart_Activate()
   
          End Sub 

   NOTE: The Activate event is the default event for the object.



5. In the Class1 (Code) window, click Resize in the Procedure list.
   
   The following code automatically appears in the class module:

   
          Private Sub EmbChart_Resize()
   
          End Sub 




6. Type the following code for the Resize event procedure:

   
          Private Sub EmbChart_Resize()
              MsgBox "You are resizing the " & EmbChart.Name & " chart."
          End Sub 




7. On the Insert menu, click Module.



8. In this module, type the following code:

   
          Dim mychart As New Class1
   
          Sub Set_Chart()
   
              Set mychart.EmbChart = Sheet1.ChartObjects(1).Chart
   
          End Sub 




9. Run the Set_Chart macro.
   
   Whenever you resize the chart on Sheet1, a message box displays the message in the EmbChart_Resize subprocedure.



10. To switch to Microsoft Excel, press OPTION+F11.



11. Click once on the embedded chart in Sheet1.



12. Click one of the handles on the border of the chart and drag it in any direction.
    
    A message box appears and displays the following message:

    You are resizing the Sheet1 Chart 1 chart.




13. Click OK.

Disabling the Event Handler

1. Start the Visual Basic Editor by pressing OPTION+F11.



2. In the general module in which you typed the Set_Chart macro, type the following macro:

   
         Sub Reset_Chart()
   
             Set mychart.EmbChart = Nothing
   
         End Sub 




3. Run the Reset_Chart macro.



4. On the File menu, click "Close and Return to Microsoft Excel."



5. Select and resize the embedded chart.

REFERENCES

For more information about using class modules, from the Visual Basic Editor, click Contents And Index on the Help menu (or on the Balloon Help menu if you are using a version of the Macintosh operating system earlier than 8.0), click the Index button in Microsoft Excel Help, type the following text

class

Additional query words: XL98 Chart

Keywords : kbprg xlvbahowto xlvbainfo
Version : MACINTOSH:98
Platform : MACINTOSH
Issue type : kbhowto