ACC: How to Create an SQL Pass-Through Query in Code

ID: Q112108

The information in this article applies to:

Microsoft Access versions 2.0, 7.0, 97

SUMMARY

Moderate: Requires basic macro, coding, and interoperability skills.

This article shows you how to create an SQL pass-through (SPT) query in Visual Basic for Applications (or Access Basic in version 2.0). You can use SPT queries to pass SQL statements directly to an ODBC data source, avoiding the need to link tables.

This article assumes that you are familiar with Visual Basic for Applications and with creating Microsoft Access applications using the programming tools provided with Microsoft Access. For more information about Visual Basic for Applications, please refer to your version of the "Building Applications with Microsoft Access" manual.

NOTE: Visual Basic for Applications is called Access Basic in Microsoft Access version 2.0. For more information about Access Basic, please refer to the "Building Applications" manual.

NOTE: A demonstration of the technique used in this article can be seen in the sample file, Qrysmp97.exe. For information about how to obtain this sample file, please see the following article in the Microsoft Knowledge Base:

Q182568 ACC97: Microsoft Access 97 Sample Queries Available in Download Center

MORE INFORMATION

You can use SPT queries to send commands directly to an ODBC database server (such as Microsoft SQL Server). Using Visual Basic (or Access Basic), you can write a function that creates an SPT query. When you run the query, it send commands directly to the ODBC database server for processing.

The following example demonstrates how to create an SPT query in code:

NOTE: In the following sample code, an underscore (_) at the end of a line is used as a line-continuation character. Remove the underscore from the end of the line when re-creating this code in Access Basic.

Create a module and type the following line in the Declarations section if it is not already there:
Option Explicit

Type the following procedure:


      Function CreateSPT (SPTQueryName As String, SQLString As String, _
                  ConnectString As String)
      '-----------------------------------------------
      ' FUNCTION: CreateSPT()
      ' PURPOSE:
      '   Creates an SQL pass-through query using the supplied arguments:
      '      SPTQueryName: the name of the query to create
      '      SQLString: the query's SQL string
      '      ConnectString: the ODBC connect string, this must be at
      '         least "ODBC;"
      '-----------------------------------------------
         Dim mydatabase As Database, myquerydef As QueryDef

         Set mydatabase = DBENGINE.Workspaces(0).Databases(0)
         Set myquerydef = mydatabase.CreateQueryDef(SPTQueryName)

         myquerydef.connect = ConnectString
         myquerydef.sql = SQLString
         myquerydef.Close
      End Function

To test this function, type the following line in the Debug window (or Immediate window in version 2.0), and then press ENTER:
```
      ? CreateSPT("MySptQuery", "sp_help", "ODBC;") 
```

This creates the query MySptQuery and adds it to the list of queries in the Database window. When you run MySptQuery it prompts you for the ODBC connect string and runs the stored procedure sp_help, which returns a list of tables from the SQL Server.

To create an SPT query called Test that returns a list of all the records from the Authors table located on the Red server in the Pubs database, you type


   ? CreateSPT("Test", "Select * from authors",_
        "ODBC;DSN=Red;Database=Pubs;USID=JOE;PWD=JOE")

in the Debug window (or Immediate window in version 2.0). This example also includes the UserId and password (both "Joe") arguments in the ODBC connect string. Note that if you do not supply at least "ODBC;" as the connect string, you receive the following error message:

Syntax error in SELECT statement.

REFERENCES

For more information about pass-through queries, search the Help Index for "pass-through queries," or ask the Microsoft Access 97 Office Assistant.

For more information about the syntax of SQL pass-through queries, please consult the documentation for your server.

Additional query words: spt

Keywords : kbusage QryPass OdbcOthr
Version : WINDOWS:2.0,7.0,97
Platform : WINDOWS
Issue type : kbhowto