ACC: How to Detect User Idle Time or Inactivity

• Microsoft Access versions 2.0, 7.0, 97

SUMMARY

Moderate: Requires basic macro, coding, and interoperability skills.

This article shows you how to create a procedure that will run if your Microsoft Access application does not detect any user input for a specified period of time.

This article assumes that you are familiar with Visual Basic for Applications and with creating Microsoft Access applications using the programming tools provided with Microsoft Access. For more information about Visual Basic for Applications, please refer to the "Building Applications" manual.

NOTE: Visual Basic for Applications (used in Microsoft Access 7.0 and Microsoft Access 97) is called Access Basic in version 2.0.

NOTE: This article explains a technique demonstrated in the sample files, FrmSampl.exe (for Microsoft Access for Windows 95 version 7.0) and FrmSmp97.exe (for Microsoft Access 97). For information about how to obtain these sample files, please see the following articles in the Microsoft Knowledge Base:

Q150895 ACC95: Microsoft Access Sample Forms Available in Download Center

Q175066 ACC97: Microsoft Access 97 Sample Forms Available in Download Center

MORE INFORMATION

How to Create the DetectIdleTime Form

1. Create a blank form that is not based on any table or query and name it DetectIdleTime.



2. Set the following form properties:

   OnTimer: [Event Procedure]
   TimerInterval: 1000

   NOTE: The TimerInterval setting indicates how often (in milliseconds) the application checks for user inactivity. A setting of 1000 equals 1 second.



3. Enter the following code for the OnTimer property event procedure:
   
   NOTE: In the following sample code, an underscore (_) at the end of a line is used as a line-continuation character. Remove the underscore from the end of the line when re-creating this code in Access Basic.

   
         Sub Form_Timer()
            ' IDLEMINUTES determines how much idle time to wait for before
            ' running the IdleTimeDetected subroutine.
            Const IDLEMINUTES = 5
   
            Static PrevControlName As String
            Static PrevFormName As String
            Static ExpiredTime
   
            Dim ActiveFormName As String
            Dim ActiveControlName As String
            Dim ExpiredMinutes
   
            On Error Resume Next
   
            ' Get the active form and control name.
   
            ActiveFormName = Screen.ActiveForm.Name
            If Err Then
               ActiveFormName = "No Active Form"
               Err = 0
            End If
   
            ActiveControlName = Screen.ActiveControl.Name
               If Err Then
               ActiveControlName = "No Active Control"
               Err = 0
            End If
   
            ' Record the current active names and reset ExpiredTime if:
            '    1. They have not been recorded yet (code is running
            '       for the first time).
            '    2. The previous names are different than the current ones
            '       (the user has done something different during the timer
            '        interval).
            If (PrevControlName = "") Or (PrevFormName = "") _
              Or (ActiveFormName <> PrevFormName) _
              Or (ActiveControlName <> PrevControlName) Then
               PrevControlName = ActiveControlName
               PrevFormName = ActiveFormName
               ExpiredTime = 0
            Else
               ' ...otherwise the user was idle during the time interval, so
               ' increment the total expired time.
               ExpiredTime = ExpiredTime + Me.TimerInterval
            End If
   
            ' Does the total expired time exceed the IDLEMINUTES?
            ExpiredMinutes = (ExpiredTime / 1000) / 60
            If ExpiredMinutes >= IDLEMINUTES Then
               ' ...if so, then reset the expired time to zero...
               ExpiredTime = 0
               ' ...and call the IdleTimeDetected subroutine.
               IdleTimeDetected ExpiredMinutes
            End If
         End Sub 




4. Create the following procedure in the form module:

   
          Sub IdleTimeDetected (ExpiredMinutes)
            Dim Msg As String
            Msg = "No user activity detected in the last "
            Msg = Msg & ExpiredMinutes & " minute(s)!"
            MsgBox Msg, 48
         End Sub 

How to Use the DetectIdleTime Form

   Macro Name   Action
   ---------------------
   AutoExec     OpenForm

   AutoExec Actions
   ----------------------------
   OpenForm:
      Form Name: DetectIdleTime
      View: Form
      Filter Name:
      Where Condition:
      Data Mode: Edit
      Window Mode: Hidden 

   Sub IdleTimeDetected (ExpiredMinutes)
      Application.Quit acSaveYes
   End Sub 

   Sub IdleTimeDetected (ExpiredMinutes)
      Application.Quit A_SAVE
   End Sub 

REFERENCES

For more information about the Timer event, search the Help Index for Timer event.

Additional query words:

Keywords : kbusage FmsHowto
Version : WINDOWS:2.0,7.0,97
Platform : WINDOWS
Issue type : kbhowto