XL97: How to Display a UserForm Whose Name Is in a Variable

ID: Q157609

The information in this article applies to:

Microsoft Excel 97 for Windows

SUMMARY

In Microsoft Excel 97, it is possible for a Visual Basic for Applications macro to display a UserForm whose name is stored in a variable. This article explains how this may be done.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

In all following examples, the UserForm being used is called "UserForm1" (without the quotation marks).

In Microsoft Excel 97, if you want a Visual Basic macro to display UserForm1, the line of code would be:


   UserForm1.Show

Although this syntax is very simple, it can cause problems if you want to show a UserForm whose name is stored in a variable. For example, if the variable "x" contains the name of the UserForm, you cannot simply use


   Sub Test()
       x = "UserForm1"
       x.Show
   End Sub

to display UserForm1.

If you run this macro, you receive the following error message:

Run-time error '424'
Object Required

UserForm Name Stored in a Variable

If you want to show a UserForm whose name is stored in a variable, you can use the following code:


   Sub ShowUserForm1()
       X = "UserForm1"
       VBA.UserForms.Add(X).Show
   End Sub

User Prompted for UserForm Name

You can use the InputBox method to ask users what UserForm they want to show:


    Sub ShowUserForm2()
       X = InputBox("Show which UserForm?: ")
       VBA.UserForms.Add(X).Show
   End Sub

UserForm Name Retrieved from Worksheet Cell

You can read a value from a cell in a worksheet:


Sub ShowUserForm3()

       'Cell A1 of Sheet1 contains the name of the UserForm
       X = ActiveWorkbook.Sheets("Sheet1").Cells(1, 1).Value

       VBA.UserForms.Add(X).Show
   End Sub

Prompt for Index Number to Display UserForm

You can include a list of UserForm names in your macro and set the value of "X" to the UserForm that corresponds to an index number.

NOTE: The following example assumes you have 3 UserForms in your project: UserForm1, UserForm2, and UserForm3. You may want to insert some macro code to make sure the value entered is between 1 and 3, inclusive.


   Sub ShowUserForm4()

       'Display an input box asking for a number between 1 and 3
       '(inclusive).
       Y = Application.InputBox (Prompt:="enter 1, 2, or 3", Type:=1)

       'Based on the number entered in the input box, X will be set to
       'the appropriate string.

       Select Case Y
           Case 1
               X = "UserForm1"
           Case 2
               X = "UserForm2"
           Case Else
               X = "UserForm3"
       End Select

       VBA.UserForms.Add(X).Show
   End Sub

In each case above, the UserForm you want to show must exist. If it does not exist in your project, you will receive the following error message

Run-time error '424'

and your macro will halt.

Additional query words: XL97 8.0 vbe user form

Keywords : kberrmsg kbprg kbdta kbdtacode xlvbainfo KbVBA
Version : WINDOWS:
Platform : WINDOWS
Issue type : kbhowto