PPT97: Paste Special Not Available in PowerPoint Object Model

• Microsoft PowerPoint 97 For Windows

SUMMARY

The Paste Special command is not available within the Microsoft PowerPoint object model. To emulate a Paste Special command, use an object model, such as the Microsoft Word object model, that supports the Paste Special command. This article provides a sample Microsoft Visual Basic for Applications macro (Sub procedure) that uses the Microsoft Word object model to emulate the Paste Special command in PowerPoint.

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft Support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp

1. Start the Visual Basic Editor. On the Tools menu, point to Macros, and then click Visual Basic Editor.



2. On the Tools menu, click References.



3. In the References - VBAProject dialog box, click to select the following two options from the Available References list:

   Microsoft PowerPoint 8.0 Object Library
   Microsoft Word 8.0 Object Library




4. Click OK.

Sub PowerPointPasteSpecial()

   On Error Resume Next
   Err.Clear

   Dim MyDoc As Word.Document
   Dim lSlideNum As Long

   'Copies the current selection in PowerPoint to the clipboard.
   'If nothing is selected a run-time error will occur.
   PowerPoint.ActiveWindow.Selection.Copy
   If Err.Number <> 0 Then
      MsgBox "Nothing is selected or not in a valid view.", _
         vbExclamation, "Invalid Selection"
      End
   End If

   'Get the current slide number.
   lSlideNum = ActiveWindow.Selection.SlideRange.SlideNumber

   'Creates a new document in Word.
   Set MyDoc = Word.Documents.Add()
   If Err.Number <> 0 Then
      MsgBox "Word is not running or available. Start Word and " _
         & "run the macro again.", vbExclamation, "Word Not Running"
      End
   End If

   'Pastes the information on the Clipboard into the Word document as
   'an Enhanced Metafile. If the information on the Clipboard is text
   'you receive a run-time error. Text does not support pasting as
   'a metafile.
   Word.ActiveWindow.Selection.PasteSpecial _
      DataType:=wdPasteEnhancedMetafile
   If Err.Number <> 0 Then
 MsgBox "Object information not on the Clipboard. Select an object " _
      & "in PowerPoint and run the macro again." & Chr(13) & Chr(13) _
      & "Having text information in the clipboard would cause this" _
         & " problem.", vbExclamation, "Incorrect Data In Clipboard"
      End
   End If

   'Copies the object, which is now an enhanced metafile to Clipboard.
   Word.ActiveWindow.Selection.Copy

   'Pastes the metafile onto the PowerPoint slide.
   PowerPoint.ActivePresentation.Slides(lSlideNum).Shapes.Paste

   'Close the document without saving changes.
   MyDoc.Close (wdDoNotSaveChanges)

End Sub 

REFERENCES

For more information about creating Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type how to create a macro click Search, and then click to view "Create a macro in Visual Basic Editor."

For more information about running Visual Basic for Applications macros, click the Office Assistant in Microsoft PowerPoint, type how to run a macro click Search, and then click to view "Run a macro."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

Q176476 OFF: Office Assistant Not Answering Visual Basic Questions

Q163435 VBA: Programming Resources for Visual Basic for Applications

Additional query words: 97 8.00 kbmacro kbpptvba ppt8 vba vbe

Keywords : kbcode kbmacro kbprg kbdta kbdtacode kbpptvba
Version : WINDOWS:97
Platform : WINDOWS
Issue type : kbhowto