OFF97: Macro That Retrieves the Number of Files in a Directory

• Microsoft Visual Basic for Applications, included with:
  • Microsoft Excel 97 for Windows
  • Microsoft PowerPoint 97 For Windows
  • Microsoft Word 97 for Windows

SUMMARY

This article includes a sample Microsoft Visual Basic for Applications function that retrieves the total number of files that exist in a specified directory. The article also includes a procedure that demonstrates how to use the function.

MORE INFORMATION

Microsoft provides examples of Visual Basic for Applications procedures for illustration only, without warranty either expressed or implied, including, but not limited to the implied warranties of merchantability and/or fitness for a particular purpose. The Visual Basic procedures in this article are provided 'as is' and Microsoft does not guarantee that they can be used in all situations. While Microsoft support professionals can help explain the functionality of a particular macro, they will not modify these examples to provide added functionality, nor will they help you construct macros to meet your specific needs. If you have limited programming experience, you may want to consult one of the Microsoft Solution Providers. Solution Providers offer a wide range of fee-based services, including creating custom macros. For more information about Microsoft Solution Providers, call Microsoft Customer Information Service at (800) 426-9400.

'--------------------------------------------------------------
' Procedure       CountAllFiles()
'
' Arguments       strDirName: A string that represents the path
'                 to the directory you want to check.
'
' Returns         The number of files in a specified directory.
'                 If the directory is not valid, the function
'                 returns 0.
'
' Description     This function retrieves the total number
'                 of all files in a specified directory.
'--------------------------------------------------------------
Function CountAllFiles(strDirName As String) As Long

   Dim oSearch As FileSearch

   ' Get a reference to the FileSearch object.
   Set oSearch = Application.FileSearch

   With oSearch

      ' Resets the search.
      .NewSearch

      ' Specify the directory that contains the files you want to
      ' count. The variable strDirName is the parameter of the
      ' CountAllFiles() function.
      .LookIn = strDirName

      ' Exclude subfolders.
      .SearchSubFolders = False

      ' Specify what types of files you want to find.
      ' For example, to search for text files change this line to:
      '   .FileName "*.txt"
      .FileName = "*.*"

      'The Execute command begins the search.
      .Execute

      ' Count the number of files in the specified directory.
      CountAllFiles = .FoundFiles.Count

   End With

End Function

' The following example calls the CountAllFiles() ' function.

Sub TestCountFiles()

   ' Change this to the directory you want to check.
   Const strMyDirectory As String = "c:\temp"

   ' This holds the total number of files found.
   Dim lFileTotal As Long

   ' Call the function. Pass the directory to check.
   lFileTotal = CountAllFiles(strMyDirectory)

   ' Display the total files found in a message box.
   MsgBox lFileTotal

End Sub 

Additional query words: wordcon 8.00 kbmacro ppt8 vba vbe ppt97 xlvbainfo

Keywords : kbprg
Version : WINDOWS:
Platform : WINDOWS
Issue type : kbhowto