WD97: How to Print a Field Result on the Last Page of a Document

ID: Q182430

The information in this article applies to:

Microsoft Word 97 for Windows

SUMMARY

This article describes how to automatically place the file name of the current document (or any other field result) on the last page of every document based on the Normal template or, using a Visual Basic for Applications macro, just the current document.

MORE INFORMATION

Method 1: On the last page of every document based on the Normal template

To place the file name on the last page of every document based on the Normal template, follow these steps:

On the File Menu, click Open.

In the List Files Of Type list, click Document Templates.

Select the folder where your templates are stored. For example, select the C:\MSOffice\Templates or C:\Winword folder.

Click the Normal template (Normal.dot), and click Open.

On the View menu, click Header And Footer.

The first button on the left on the Header And Footer toolbar toggles between the header and footer. Toggle to the one that you want the field to appear in.

Press CTRL+F9 (Windows) or COMMAND+F9 (Macintosh) to insert a field.

Type the following in the field brackets
```
      if { page }={ numpages } "{ filename \p }" 
```
so that the field looks like this:
```
     { if { page } = { numpages } "{ filename \p }" } 
```
NOTE: The \p switch causes the entire path to the file name to be included.

NOTE: The field brackets are actual fields and the code should not be copied. They should be entered as separate fields. In other words, each set of brackets corresponds to a field.

On the File menu, click Save. Close the file.

Method 2: Use a macro to place the file name on last page of a document

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact the Microsoft fee-based consulting line at (800) 936-5200. For more information about the support options available from Microsoft, please see the following page on the World Wide Web:

http://www.microsoft.com/support/supportnet/overview/overview.asp


   Sub PutFileNameOnLastPage()
      ' Are any documents open?
      If Documents.Count = 0 Then Exit Sub
      ' Go to footer of document in the last section
      ' of the document.
      Selection.EndKey Unit:=wdStory
      If ActiveWindow.ActivePane.View.Type = wdNormalView Or _
         ActiveWindow.ActivePane.View.Type = wdOutlineView Or _
           ActiveWindow.ActivePane.View.Type = wdMasterView Then
         ActiveWindow.ActivePane.View.Type = wdPageView
      End If
      ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageFooter
      ' If the document already contains a filename, exit this routine.
      For Each ao In Selection.HeaderFooter.Range.Fields
         If ao.Type = wdFieldFileName Then
            MsgBox "This document already contains a filename."
            Exit Sub
         End If
      Next
      ' Add the Filename field.
      ActiveWindow.View.ShowFieldCodes = True
      With Selection
         .Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, Text:= _
            "IF ", PreserveFormatting:=True
         .MoveRight Unit:=wdCharacter, Count:=5
         .Fields.Add Range:=Selection.Range, Type:=wdFieldPage
         .TypeText Text:=" = "
         .Fields.Add Range:=Selection.Range, Type:=wdFieldNumPages
         .TypeText Text:=" "
         .Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, Text:= _
            "FILENAME \p "
         Selection.HeaderFooter.Range.Fields.Update
      End With
      ' Turn field codes off.
      ActiveWindow.View.ShowFieldCodes = False
      ' Close the footer and return to document.
      ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
   End Sub

The If field determines whether the current page equals the number of pages in the document. This field is present in the header or footer on every page in the document. However, the file name will be printed only on the final page of the document. These steps can be used with any field (that is, you can substitute another field code for the file name if you want different results to print, such as the date).

For additional information, please see the following article in the Microsoft Knowledge Base:

Q173707

OFF97: How to Run Sample Code from Knowledge Base Articles

REFERENCES

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

Q163435 VBA: Programming Resources for Visual Basic for Applications

Additional query words: wordcon vb vba vbe

Keywords : kbcode kbprg kbdta kbdtacode kbmacroexample word97
Version : WINDOWS:97
Platform : WINDOWS
Issue type : kbinfo