Basic Example Using SETMEM to Allocate Far Heap Memory; EXEMOD

• Microsoft Visual Basic Standard and Professional Editions for MS-DOS, version 1.0
• Microsoft QuickBASIC for MS-DOS, versions 4.0, 4.0b, 4.5
• Microsoft BASIC Compiler for MS-DOS, versions 6.0, 6.0b
• Microsoft BASIC Professional Development System (PDS) for MS-DOS, versions 7.0, 7.1

SUMMARY

To allocate a reserved location in memory that compiled Basic will not touch, you can deallocate some memory by using the SETMEM function (see the Basic language reference manual and the example for SETMEM below). Then, using either CALL INTERRUPT or CALL INT86OLD, execute a MS-DOS Interrupt 21 hex (33 decimal), with function 48 hex (72 decimal) to obtain the address of the memory freed in far memory. Call with AX equal to &H4800 and BX equal to the number of paragraphs of memory needed (the number of bytes of memory needed, divided by 16).

If the function succeeds, the flag is clear and AX returns the initial segment (paragraph address) of the allocated block.

If the function fails, the flag is set and AX either is 7 (if memory control blocks were destroyed) or 8 (if memory was insufficient, in which case BX gives the size of the largest available block).

MORE INFORMATION

Please note that QuickBasic for MS-DOS, versions 3.0 and earlier do not include the SETMEM function.

The following are two other methods of allocating areas of memory:

1. A static array can be set aside as a block of memory that will not move. The VARPTR function returns the offset of the array.



2. The EXEMOD.EXE utility provided with the Microsoft Macro Assembler allows you to modify the header of an .EXE to shorten the maximum upper load address of a program. By default, Basic .EXE programs assume that all of RAM is available. If you make the load address smaller, you must make sure that there is enough room for the Basic program's code and data. Microsoft does not encourage using EXEMOD with compiled Basic programs. The SETMEM function should be used instead.

Example

' To try this example in VBDOS.EXE:
' 1. From the File menu, choose New Project.
' 2. Copy the code example to the Code window.
' 3. Press F5 to run the program.

' To run this program in the environment, you must invoke the
' environment with the /L switch to load the default Quick library:
'    VBDOS.EXE /L          for Visual Basic 1.0 for MS-DOS

' Use the following include file for Visual Basic 1.0 for MS-DOS:
REM $INCLUDE: 'VBDOS.BI'

DEFINT A-Z
DIM InRegs AS RegType, OutRegs AS RegType
DIM InRegsX AS RegTypeX, OutRegsX AS RegTypeX

PRINT SETMEM(-1808)     ' Have Visual Basic free up some memory.
InRegs.ax = &H4800
InRegs.bx = 113         ' Allocates a block of 113 paragraphs, or
                        ' 113*16 bytes.
CALL INTERRUPT(&H21, InRegs, OutRegs)

' Check results of the interrupt call.
IF (OutRegs.flags AND 1) = 0 THEN
     PRINT "Eureka!   Memory allocated at &H"; HEX$(OutRegs.ax)
ELSEIF OutRegs.ax = 7 THEN
     PRINT "ERROR!  Memory control blocks destroyed!"
     END
ELSE
     PRINT "Insufficient memory!  Largest available block is: "
           ;OutRegs.bx
     END
END IF

' Now deallocate the memory we just allocated.
InRegsX.es = OutRegs.ax
InRegsX.ax = &H4900
CALL INTERRUPTX(&H21, InRegsX, OutRegsX)

' Double check the outcome of the interrupt call.
IF (OutRegsX.flags AND 1) = 0 THEN
     PRINT "Memory successfully deallocated."
ELSEIF OutRegsX.ax = 7 THEN
     PRINT "ERROR!  Memory Control Blocks destroyed!"
ELSE
     PRINT "ERROR!  Incorrect segment in ES!"
END IF 

Additional query words: VBmsdos BasicCom

Keywords :
Version : MS-DOS:1.0,4.0,4.0b,4.5; :6.0,6.0b,7.0,7.1
Platform : MS-DOS
Issue type :