Properties Collection Object

See Also         Properties         Methods        

A collection of meta data as Property objects. Each item in the Properties collection represents an item associated with an individual Web, WebFile, or WebFolder object. For more information, refer to the table of PropertyKeys in Using the PropertyKeys. Choose a topic from the following list to go directly to that topic.

Using the Properties Object

Using the Properties Collection Within a Web

Using the PropertyKeys

Using the Properties Object

Use the Add method to add a property to the Properties collection. The following statement adds a copyright statement to the Properties collection.

ActiveWeb.Properties.Add "Copyright", _
    “Copyright 1999 by Rogue Cellars”)

You can also add and remove categories and approval levels.

Use the ApplyChanges method to apply a Property object that has been added to the collection of Properties. The following statements add and apply a copyright property to the Properties collection.

ActiveWeb.Properties.Add "Copyright", _
    “Copyright 1999 by Rogue Cellars”)
ActiveWeb.Properties.ApplyChanges

Use the Count property to return the total number of properties in the Properties collection. The following example checks that the number of properties in the Properties collection has increased since the Copyright property was added and applied to the collection, and then goes on to add the copyright to a web page.

Note   To run this example, you must have a web called "C:\My Documents\My Webs\Rogue Cellars" (for a server running on Microsoft Windows) or "C:\WINNT\Profiles\logon alias\Personal\My Webs\Rogue Cellars" (for a server running on Windows NT). In either case, you may substitute an alternative web URL or file.

Private Sub copyrightAdd()
Dim myWeb As Web
Dim myCopyright As String
Dim myCount As Integer
Dim myMessage As String

myCopyright = "Copyright 1999 by Rogue Cellars"
myCount = ActiveWeb.Properties.Count
myMessage = "No new properties have been added."

Set myWeb = Webs.Open("C:\My Webs\Rogue Cellars")
myWeb.Activate
ActiveWeb.Properties.Add "Copyright", myCopyright

If myCount <> ActiveWeb.Properties.Count – 1 Then
    MsgBox myMessage
    Exit Sub
End If

ActiveWeb.RootFolder.Files("Zinfandel.htm").Open
ActiveDocument.body.insertAdjacentText "BeforeEnd", _
    ActiveWeb.Properties("Copyright")
ActivePageWindow.Save
ActiveWeb.Close
End Sub

Use the Delete method to delete a single property. The following statement deletes the Copyright property from the Properties collection.

ActiveWeb.Properties.Delete("Copyright")

Use the Parent property when you want to return the container for the Properties collection. For example, the following statement returns the URL of the parent web.

myParentURL  = ActiveWeb.Properties.Parent.Url

Using the Properties Collection Within a Web

Use Properties(index), where index is the PropertyKey of the item in the Properties collection, to return a single property. The following example returns the value of the PropertyKey vti_hassearchbot.

Private Sub CheckForSearchBot()
Dim myProperties As Properties
Dim myFoundSearchBot As Boolean

Set myProperties = ActiveWeb.Properties

With myProperties
    myFoundSearchBot = .Item("vti_hassearchbot")
End With
End Sub

Important   The values for properties are variant—that is, each value can be a string, a Boolean, or an array. You can use the Typename() function to determine the type of the property value.

Note   To run the following example you must create a form that contains a text box called txtCategories. Also, notice that myCategories is declared as a variant type in this example. In a previous example, myFoundSearchBot was declared Boolean—but could also have been declared as a string.

Private Sub GetWebPropertyCategories()
Dim myProperties As Properties
Dim myCategories As Variant
Dim myCategory As Variant
Dim txtCategories As String

Set myProperties = ActiveWeb.Properties

With myProperties
    myCategories = .Item("vti_categories")
    For Each myCategory In myCategories
        txtCategories = txtCategories & "|" & myCategory
    Next
End With
End Sub

Using the PropertyKeys

The property keys can be a valuable tool for organizing information about your webs. For example, you can add categories to the master list of categories on your web.

Important   The category names can be added to the categories list using case sensitivity, but will not display with case sensitivity in the User Interface (UI). Because of this, a situation may occur where a user creates a category on the client, such as "Web Administrators", and a duplicate category exists on the server, such as "web administrators". In this case, in the UI, FrontPage will assign both categories to the "web administrators" category and neither of these can be deleted from the web (in the UI). Programmatically, the case sensitivity will correctly display in the Immediate and Local windows of the Visual Basic Editor.

The following example first adds a category to the properties for the active web, deletes the Waiting category from the same list (vti_categories), and then adds the new category to each of the files in the active web.

Note   When creating a new category, you must first add the new category to the web before you add it to any of the files. The procedure, AddCategories, adds a new category to the web and the next procedure, AddCategoryToFiles, adds the same category to all of the files in the web.

Private Sub AddCategories()
Dim myWeb As Web
Dim myCategory(2) As String
Dim myItem As Variant

Set myWeb = ActiveWeb
myCategory(0) = "+web administrators"
myCategory(1) = "-waiting"
ActiveWeb.Properties("vti_categories") = myCategory
ActiveWeb.Properties.ApplyChanges

'List all of the items in vti_categories in the Immediate window
For Each myItem In myWeb.Properties("vti_categories")
    Debug.Print myItem
Next
End Sub

Private Sub AddCategoryToFiles()
Dim myWeb As Web
Dim myCategories(1) As String
Dim myFiles As WebFiles
Dim myFile As WebFile
Dim myItem As Variant

Set myWeb = ActiveWeb
Set myFiles = myWeb.RootFolder.Files
myCategories(0) = "+web administrators"

For Each myFile In myFiles
    myFile.Properties("vti_categories") = myCategories
    myFile.Properties.ApplyChanges
    'List all the items in vti_categories in the Immediate window
    For Each myItem In myFile.Properties("vti_categories")
        Debug.Print myItem
    Next
Next
End Sub

Note   Although you can create new categories, such as "web administrators", that aren't included in the categories that are automatically installed with FrontPage, these new categories won't be visible in the User Interface (UI) until they are added to the web. Notice that in the previous example, the new category was added to the web first and will be visible in the UI.

The following table provides detailed information about the property keys available in FrontPage 2000. Notice that all property keys in FrontPage start with “vti_”. It is suggested that you prefix the property keys you want to add with a short name, such as an abbreviation for the name of your company, to reduce chances of naming conflicts with other properties.