Hyperlink Property

Applies To Combo Box control, Command Button control, Image control, Label control, Text Box control.

Description

You can use the Hyperlink property to return a reference to a hyperlink object. You can use the Hyperlink property to access the properties and methods of a Hyperlink object associated with a control.

Setting

The Hyperlink property is available only by using Visual Basic.

See Also AddToFavorites method, Follow method, FollowHyperlink method, HyperlinkAddress property, HyperlinkPart function, HyperlinkSubAddress property.

Example

The CreateHyperlink procedure in the following example sets the hyperlink properties for a command button, label, or image control to the address and subaddress values passed to the procedure. The address setting is an optional argument, because a hyperlink to an object in the current database uses only the subaddress setting, To try this example, create a form with two text box controls (txtAddress and txtSubAddress) and a command button (cmdFollowLink) and paste the following into the Declarations section of the form's module:

Private Sub cmdFollowLink_Click()
    CreateHyperlink Me!cmdFollowLink, Me!txtSubAddress, Me!txtAddress
End Sub

Sub CreateHyperlink(ctlSelected As Control, strSubAddress As String, _
        Optional strAddress As String)
    Dim hlk As Hyperlink
    Select Case ctlSelected.ControlType
        Case acLabel, acImage, acCommandButton
            Set hlk = ctlSelected.Hyperlink
            With hlk
                If Not IsMissing(strAddress) Then
                    .Address = strAddress
                Else
                    .Address = ""
                End If
                .SubAddress = strSubAddress
                .Follow
                .Address = ""
                .SubAddress = ""
            End With
        Case Else
            MsgBox "The control '" & ctlSelected.Name _
                & "' does not support hyperlinks."
    End Select
End Sub