Item Method

Applies To

Controls collection, Pages collection, Tabs collection.

Description

Returns a member of a collection, either by position or by name.

Syntax

Set Object = object.Item( collectionindex)

The Item method syntax has these parts:

Part	Description

object	Required. A valid object.
collectionindex	Required. A member's position, or index, within a collection.

Settings

The collectionindex can be either a string or an integer. If it is a string, it must be a valid member name. If it is an integer, the minimum value is 0 and the maximum value is one less than the number of items in the collection.

Remarks

If an invalid index or name is specified, an error occurs.

Example

The following example uses the Item method to access individual members of the Controls and Pages collections. The user chooses an option button for either the Controls collection or the MultiPage, and then clicks the CommandButton. The name of the appropriate control is returned in the Label.

To use this example, copy this sample code to the Declarations portion of a form. Make sure that the form contains:

A CommandButton named CommandButton1.
A Label named Label1.
Two OptionButton controls named OptionButton1 and OptionButton2.

A MultiPage named MultiPage1.

Dim MyControl As Object
Dim ControlsIndex As Integer

Private Sub CommandButton1_Click()
    If OptionButton1.Value = True Then
        'Process Controls collection for UserForm
        Set MyControl = Controls.Item(ControlsIndex)
        Label1.Caption = MyControl.Name

        'Prepare index for next control on Userform
        ControlsIndex = ControlsIndex + 1
        If ControlsIndex >= Controls.Count Then
            ControlsIndex = 0
        End If
    
    ElseIf OptionButton2.Value = True Then
        'Process Current Page of Pages collection
        Set MyControl = MultiPage1.Pages.Item(MultiPage1.Value)
        Label1.Caption = MyControl.Name
    End If
End Sub

Private Sub UserForm_Initialize()
    ControlsIndex = 0
    'TabsIndex = 0
    
    OptionButton1.Caption = "Controls Collection"
    OptionButton2.Caption = "Pages Collection"
    OptionButton1.Value = True
    
    CommandButton1.Caption = "Get Member Name"
End Sub