This script is invoked when the user responds to a request for clarification. It works similarly to Response.asp, except it operates on a saved conversation context, rather than beginning a new dialog with the end user.
<!-------------------------------------------------------------------
Microsoft English Query
Copyright 1998 Microsoft Corporation. All Rights Reserved.
Component: Sample Scripts
File: Clarify.asp
Clarification Page
-------------------------------------------------------------------->
<!--#include file=common.inc -->
<HTML>
<BASEFONT FACE="Arial">
<HEAD>
<TITLE>English Query Response</TITLE>
</HEAD>
<BODY BGCOLOR="#FFFFFF" TEXT="#000000">
<%
If Not IsObject(Session("EQResponse")) or Session("EQResponse") Is Nothing Then
Response.Write("Sorry, your conversation context is no longer available.<BR>Please ask your question again.<BR>")
Response.End
End If
Set objEQResponse = Session("EQResponse")
Set objInputs = objEQResponse.UserInputs
'----- UserInput type constants -----
nlListInput = 0
nlTextInput = 1
nlStaticInput = 2
'----- Package up all user clarifications -----
For intInput = 0 to objInputs.Count - 1
Set objInput = objInputs(intInput)
strInputName = "Input" & intInput
strInput = Request.Form(strInputName)
Select Case objInput.Type
Case nlStaticInput
Case nlTextInput
objInput.Text = strInput
Case nlListInput
objInput.Selection = strInput
Case Else
Response.Write "Error: Unexepcted input type"
End Select
Next
'----- Resubmit the question by replying to the clarification response
Set objEQResponse = objEQResponse.Reply()
'----- Handle the new response
ProcessResponse objEQResponse, Session("Question")
%>
<BR><HR><BR>
</BODY>
</BASEFONT>
</HTML>